Manage multi program at the same time

[trinitrotoluen]

Hi, I'm new here. I want to make a solution to manage multi program.

For example : Open 10 notepad at the same time and type some text in 10 notepad at the same time.

How can I code ?

thx in advance !

[Olsson]

http://www.autoitscript.com/forum/index.php?showtopic=86973

Check out that topic, just under yours.

[trinitrotoluen]

http://www.autoitscript.com/forum/index.php?showtopic=86973

Check out that topic, just under yours.

Thx you for your link but it can't. I mean type some text in 10 notepad at the same time

[MrCreatoR]

Open 10 notepad at the same time and type some text in 10 notepad at the same time

Here is an example of how you can do it:

expandcollapse popup

Opt("WinWaitDelay", 150) ;In some cases may need to be increesed

$iTop = 30
$iRun_Instances = 5
$sSet_Data = "Notepad Instance #%i"

$hGUI = GUICreate("__Simultanius_Run_Handling_GUI__")
$nEdit = GUICtrlCreateEdit("", 0, 0, 200, 200)

For $i = 1 To $iRun_Instances
    Run(@WindowsDir & "\Notepad.exe")
    If @error Then ContinueLoop
    
    WinWait("[CLASS:Notepad]", "", 5)
    WinSetTitle("[CLASS:Notepad]", "", "Untitled_" & $i)
    
    $aWin_Pos = WinGetPos("Untitled_" & $i)
    WinMove("Untitled_" & $i, "", $aWin_Pos[0], $iTop)
    
    $iTop += 80
    
    $sRun_Script_Content = _
        '#NoTrayIcon' & @CRLF & _
        'While ControlGetText(Hwnd(' & $hGUI & '), "", "Edit1") <> "Notepad Instances = ' & $iRun_Instances & '"' & @CRLF & _
        '   Sleep(10)' & @CRLF & _
        'WEnd' & @CRLF & _
        'ControlSetText("[CLASS:Notepad;TITLE:Untitled_' & $i & ']", "", "Edit1", StringFormat("' & $sSet_Data & '", ' & $i & '))'
    
    $hFOpen = FileOpen(@TempDir & "\~Au3_Run_" & $i & ".Tmp", 2)
    FileWrite($hFOpen, $sRun_Script_Content)
    FileClose($hFOpen)
    
    Run(@AutoItExe & ' /AutoIt3ExecuteScript "' & @TempDir & '\~Au3_Run_' & $i & '.Tmp"')
    
    If $i = $iRun_Instances Then
        MsgBox(64, "Attention...", "Now we will see the data set almost in the same time in all [" & $i & "] Notepads...", 3)
        Sleep(500)
    EndIf
    
    GUICtrlSetData($nEdit, "Notepad Instances = " & $i)
Next

Sleep(2000)
MsgBox(64, "Attention...", "Now we need to clean a little :) (delete temporary files and close Notepad windows)...", 5)

Opt("WinWaitDelay", 0)

For $i = $iRun_Instances To 1 Step -1
    FileDelete(@TempDir & '\~Au3_Run_' & $i & '.Tmp')
    WinKill("Untitled_" & $i)
Next

Just run the script, and follow the message boxes

P.S

The concept here is quit simple: First we executing few scripts that waiting for the main Edit (of the "parent" GUI) to have specific data (in our case it is a Notepad Instances = 5), and when the last notepad process is executed, this data is set and then all scripts will "fire" (send) some string to the notepad that was preserved (by title) for this current script - so the bottom line here is that the strings are sent in the same time (for the human eye anyway, i don't think that we need here an atomic precision ).

Edited January 4, 2009 by MrCreatoR

[trinitrotoluen]

Here is an example of how you can do it:

expandcollapse popup

Opt("WinWaitDelay", 150) ;In some cases may need to be increesed

$iTop = 30
$iRun_Instances = 5
$sSet_Data = "Notepad Instance #%i"

$hGUI = GUICreate("__Simultanius_Run_Handling_GUI__")
$nEdit = GUICtrlCreateEdit("", 0, 0, 200, 200)

For $i = 1 To $iRun_Instances
    Run(@WindowsDir & "\Notepad.exe")
    If @error Then ContinueLoop
    
    WinWait("[CLASS:Notepad]", "", 5)
    WinSetTitle("[CLASS:Notepad]", "", "Untitled_" & $i)
    
    $aWin_Pos = WinGetPos("Untitled_" & $i)
    WinMove("Untitled_" & $i, "", $aWin_Pos[0], $iTop)
    
    $iTop += 80
    
    $sRun_Script_Content = _
        '#NoTrayIcon' & @CRLF & _
        'While ControlGetText(Hwnd(' & $hGUI & '), "", "Edit1") <> "Notepad Instances = ' & $iRun_Instances & '"' & @CRLF & _
        '   Sleep(10)' & @CRLF & _
        'WEnd' & @CRLF & _
        'ControlSetText("[CLASS:Notepad;TITLE:Untitled_' & $i & ']", "", "Edit1", StringFormat("' & $sSet_Data & '", ' & $i & '))'
    
    $hFOpen = FileOpen(@TempDir & "\~Au3_Run_" & $i & ".Tmp", 2)
    FileWrite($hFOpen, $sRun_Script_Content)
    FileClose($hFOpen)
    
    Run(@AutoItExe & ' /AutoIt3ExecuteScript "' & @TempDir & '\~Au3_Run_' & $i & '.Tmp"')
    
    If $i = $iRun_Instances Then
        MsgBox(64, "Attention...", "Now we will see the data set almost in the same time in all [" & $i & "] Notepads...", 3)
        Sleep(500)
    EndIf
    
    GUICtrlSetData($nEdit, "Notepad Instances = " & $i)
Next

Sleep(2000)
MsgBox(64, "Attention...", "Now we need to clean a little :) (delete temporary files and close Notepad windows)...", 5)

Opt("WinWaitDelay", 0)

For $i = $iRun_Instances To 1 Step -1
    FileDelete(@TempDir & '\~Au3_Run_' & $i & '.Tmp')
    WinKill("Untitled_" & $i)
Next

Just run the script, and follow the message boxes

Great ! Work like a charm !

[trinitrotoluen]

@TempDir is it C:\WINDOWS\Temp ? I want to find it.

Edited January 3, 2009 by trinitrotoluen

[MrCreatoR]

@TempDir is it C:\WINDOWS\Temp ? I want to find it.

ShellExecute(@TempDir)

?

[trinitrotoluen]

Hi, MrCreatoR. Is it possible to debug AutoIT like press F10 in VC 6 ?

Edited January 4, 2009 by trinitrotoluen

[MrCreatoR]

Hi, MrCreatoR. Is it possible to debug AutoIT like press F10 in VC 6 ?

I don't know how it works in VC 6, but in AutoIt you have Syntax Check (F8), plus this little tool: _AutoItErrorHandler (and few more found on the forum).

P.S

But how is that related to this topic?

[rasim]

MrCreatoR

Good example my friend!