Stumped on WindowSetState

[Encryption]

Mkay first I will start off with the code I am doing for a friend.

;Mason's Improved Internet Explorer Hide
HotKeySet("{PGUP}", "Restore")
HotKeySet("{PGDN}", "Hide")
HotKeySet("{ESC}", "Terminate")

Opt("WinTitleMatchMode", 2)

ToolTip("Explorer Hide V2.0 Is Active", 0, 0)
While 1
    
WEnd
Func Restore()
    ToolTip("Explorer Hide V2.0 Is Active", 0, 0)
    WinSetState("Microsoft Internet Explorer", "", @SW_SHOW)
EndFunc

Func Hide()
    ToolTip("", 3000, 3000)
    WinSetState("Microsoft Internet Explorer", "", @SW_HIDE)

EndFunc

Func Terminate()
    Exit 0
EndFunc

Now, this does everything needed, but I want it to Hide Multiple IE's(all that are minimized and active) and then Restore all the ones that i just hid. Possible?

[CyberSlug]

You should enumerate all windows that match the title, grab their window handles to tell them apart, and call WinSetState on each handle:

REPLACE WinSetState("Microsoft Internet Explorer", "", @SW_HIDE)

with the following:

Local $windows = WinList("Microsoft Internet Explorer")
For $i = 1 to $windows[0][0]
   WinSetState($windows[$i][1], "", @SW_HIDE)       
Next

Likewise with @SW_SHOW

[Encryption]

You should enumerate all windows that match the title, grab their window handles to tell them apart, and call WinSetState on each handle:

REPLACE WinSetState("Microsoft Internet Explorer", "", @SW_HIDE)

with the following:

Local $windows = WinList("Microsoft Internet Explorer")
For $i = 1 to $windows[0][0]
   WinSetState($windows[$i][1], "", @SW_HIDE)       
Next

Likewise with @SW_SHOW

<{POST_SNAPBACK}>

Thank you very much, helped a lot

EDIT:

There is an error where the array is declared. I am not a big fan of arrays in AutoIt, nor do I know them well. Do you see any errors?

EDIT: I fixed it, just declared a new array for the other For statement, sorry, my error.

Edited February 19, 2005 by Encryption

[CyberSlug]

There is an error where the array is declared. I am not a big fan of arrays in AutoIt, nor do I know them well. Do you see any errors?

<{POST_SNAPBACK}>

Works okay for me with zero, one, or many windows:

HotKeySet("{PGUP}", "Restore")
HotKeySet("{PGDN}", "Hide")
HotKeySet("{ESC}", "Terminate")

Opt("WinTitleMatchMode", 2)

ToolTip("Explorer Hide V2.0 Is Active", 0, 0)
While 1
    sleep(100);prevent maxing out the CPU
WEnd

Func Restore()
    ToolTip("Explorer Hide V2.0 Is Active", 0, 0)
    _SetIEState(@SW_SHOW)
EndFunc

Func Hide()
    ToolTip('')
    _SetIEState(@SW_HIDE)
EndFunc

Func _SetIEState($state)
    Local $i, $windows = WinList("Microsoft Internet Explorer")
    For $i = 1 to $windows[0][0]
        WinSetState($windows[$i][1], "", $state)        
    Next
EndFunc

Func Terminate()
    Exit 0
EndFunc

EDIT: Re-wrote code a little bit.

Edited February 19, 2005 by CyberSlug

[Encryption]

Thanks again, my friend will be very happy. I think he is going to sign up in a bit and thank you, he is an AutoIt newbie(yes, more than me) so he will be asking for help quite often.

[Lakai[NL]]

Yes, thanks alot for the help cyber, that was the last piece of the script that we needed help on

[davo818]

Ya I from rgx too

Thanks cyber

[therks]

Invasion of the newbs!

[Blue_Drache]

Invasion of the newbs!

<{POST_SNAPBACK}>

*runs around screaming "OMG WE'RE ALL GOING TO DIE!!!"*

[Insolence]

Calmly stands ground with AutoIT Help File*