Utility to show Z Order?

[qwert]

Does anyone know of a utility that can display a list of all current windows and show their Z Order setting?

I'm troubleshooting an instance where the taskbar is disappearing behind an application window.

It's a fairly rare occurrence, but I'd like to get to the bottom of it. Among other things, I've tried forcing the taskbar on top with WinSetOnTop("[class:Shell_TrayWnd]", "", 1) in the script I use to start the application. But nothing has had any effect. A certain mouse click combination causes the taskbar to occasionally disappear. So I need to be able to detect any change in the Z Order to help isolate the cause.

Thanks in advance for any assistance.

[NerdFencer]

you can see the top with the WinActive function....

[qwert]

... display a list of all current windows

I need to be able to monitor all current windows so I can detect changes in their relative order.

[MrCreatoR]

Check the ShellHookWindow by Siao.

Edited February 3, 2009 by MrCreatoR

[qwert]

Check the ShellHookWindow by Siao.

Thanks for the suggestion. I'll try to figure it out, but the following makes me think it only monitors a window that I've created with AutoIt3:

First we have to register unique message - RegisterWindowMessage("SHELLHOOK")

Then GuiRegisterMsg() the message with a handler function, and of course hook up our GUI with RegisterShellHookWindow (and unregister when not needed anymore).

And that's pretty much it.

The window I'm having the problem with is a third-party application (that I'm using AutoIt3 to resize and position). I still believe the underlying cause is something altering the Z order, which is why I'd like to be able to monitor it for all current windows.

[qwert]

This is an update to what I just posted.

I was able to compile run ShellHookWindow and monitor my problem of the disappearing taskbar. The Capture below shows what occurred as I switched from my Application to Notepad and back. After the switch, I double-clicked rapidly in an unused area of the Application's window and caused the taskbar to disappear (behind the application window). Yet, nothing changed in the ShellHook monitoring window.

Any suggestions?

[LarryDalooza]

Whipped together to tooltip the Z order... Winlist respects the Z order

expandcollapse popup

Global $buffer = ""

While 1
    ToolTip("")
    $list = WinList()
    If $list[0][0] = 0 Then Exit

    $i = 0

    For $n = 1 to $list[0][0]
        If Not IsVisible($list[$n][1]) Then ContinueLoop
        $i += 1
        If Not StringLen($list[$n][0]) Then
            $buffer &= $i & ": " & GetClassName($list[$n][1]) & @LF
        Else
            $buffer &= $i & ": " & $list[$n][0] & @LF
        EndIf
    Next

    ToolTip($buffer)
    $buffer = ""
    Sleep(1000)
WEnd

Func GetClassName(ByRef $hWnd)
    Local $ret = DLLCall("user32.dll","int","GetClassName","hwnd",$hWnd,"str","","int",5000)
    If IsArray($ret) Then
        Return $ret[2]
    Else
        Return ""
    EndIf
EndFunc

Func IsVisible($handle)
    If BitAnd( WinGetState($handle), 2 ) Then 
        Return 1
    Else
        Return 0
    EndIf
EndFunc

[qwert]

EXCELLENT! That's the tool I was hoping for.

I was able to capture the circumstance exactly. Shell_TrayWnd is normally at the top -- with my application second. But the double-action I described above sends Shell_TrayWnd almost to the very bottom, just above Program Manager. I ran my test with 20 different windows open and Taskbar went from #1 to #19. So Z order management IS the problem. Now I only have to fashion a solution in the form of some preventive measure.

Thanks very much for your help.

[E1M1]

I wonder what does GetClassName and why it is needed. I just cant understand this part

[PsaltyDS]

I wonder what does GetClassName and why it is needed. I just cant understand this part

It's not required, it was just put in to provide some useful info (each window's class name) where the title was blank. The function that performs it is right there in Larry's example. If you are not interested in the class name, don't use it.

Edited February 19, 2009 by PsaltyDS