Running a command once every X minutes but keeping the program active.

[mexykanu]

Hello,

I'm having trouble using a timer for my program. It should work as follows:

- a function is ran once every X minutes (user defined)

- the program should still be available for interacting - ONLY by System Tray, using TrayGetMsg.

I don't need to use TimerInit because the program runs at 100%.

Thanks,

mexykanu.

[BrettF]

Post your code, we aint no mind reader.

Cheers,

Brett

[mexykanu]

#Include <Constants.au3>
#NoTrayIcon

Opt("TrayMenuMode",1); Default tray menu items (Script Paused/Exit) will not be shown.

$settingsitem   = TrayCreateMenu("Settings")
$displayitem    = TrayCreateItem("Display", $settingsitem)
$printeritem    = TrayCreateItem("Printer", $settingsitem)
TrayCreateItem("")
$aboutitem      = TrayCreateItem("About")
TrayCreateItem("")
$exititem       = TrayCreateItem("Exit")

TraySetState()


While 1
    $dif=TimerDiff($start)
    $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $aboutitem
            Msgbox(64,"About:","AutoIt3-Tray-sample")
        Case $msg = $exititem
            ExitLoop
    EndSelect



WEnd
Exit

Func _givemsg()
    MsgBox(0,"","msg")
EndFunc

Hi again. Here's a sample code. I want to run _givemsg() every 2 minutes.

Thanks,

mexykanu.

[Melba23]

mexykanu,

You are not using TimerDiff correctly. This will do what you want:

expandcollapse popup

#Include <Constants.au3>
#NoTrayIcon

Opt("TrayMenuMode",1); Default tray menu items (Script Paused/Exit) will not be shown.

$settingsitem   = TrayCreateMenu("Settings")
$displayitem    = TrayCreateItem("Display", $settingsitem)
$printeritem    = TrayCreateItem("Printer", $settingsitem)
TrayCreateItem("")
$aboutitem      = TrayCreateItem("About")
TrayCreateItem("")
$exititem       = TrayCreateItem("Exit")

TraySetState()

$start = TimerInit()

While 1
    If TimerDiff($start) > 2 * 60 * 1000 Then
        _givemsg()
        $start = TimerInit()
    EndIf
    
    $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $aboutitem
            Msgbox(64,"About:","AutoIt3-Tray-sample")
        Case $msg = $exititem
            ExitLoop
    EndSelect

WEnd
Exit

Func _givemsg()
    MsgBox(0,"","msg")
EndFunc

This will restart the 2 minute delay from the moment you close the message box. If you want the box to open exactly 2 minutes after the last time it opened, just place the new TimerInit line above the function call.

M23

[BrettF]

Its not your full code, so I can't know everything about it...

But try this netherless:

#include <Constants.au3>
#NoTrayIcon

Opt("TrayMenuMode", 1); Default tray menu items (Script Paused/Exit) will not be shown.

$settingsitem = TrayCreateMenu("Settings")
$displayitem = TrayCreateItem("Display", $settingsitem)
$printeritem = TrayCreateItem("Printer", $settingsitem)
TrayCreateItem("")
$aboutitem = TrayCreateItem("About")
TrayCreateItem("")
$exititem = TrayCreateItem("Exit")

TraySetState()

$start = TimerInit ()

While 1
    $dif = TimerDiff($start)
;If $dif >= 2*1000*60 Then; SHould be 2 minutes if my calculations are correct... Otherwise i'm testing with 5 seconds
    If $dif >= 5000 Then
        _givemsg ()
        $start = TimerInit ()
    EndIf
    $msg = TrayGetMsg()
    Select
        Case $msg = $aboutitem
            MsgBox(64, "About:", "AutoIt3-Tray-sample")
        Case $msg = $exititem
            ExitLoop
    EndSelect
WEnd

Func _givemsg()
    MsgBox(0, "", "msg")
EndFunc  ;==>_givemsg

[mexykanu]

Thank you melba and brettf, that worked although i don't know why my code used the processor at 100%.

Edited February 3, 2009 by mexykanu

[weirddave]

Thank you melba and brettf, that worked although i don't know why my code used the processor at 100%.

You're looping round without taking a break, use Sleep(100) somewhere in the while loop to free up the cpu.

[mexykanu]

You're looping round without taking a break, use Sleep(100) somewhere in the while loop to free up the cpu.

That's what i used when i tried first, but it puts the whole program to sleep. I need it always active so i can right-click the icon in the systray .

Anyway, the problem was solved.

Many thanks to everyone

[Melba23]

weirddave,

There is no need to use a Sleep when using the GUIGetMsg or TrayGetMsg functions - from the Help file for both functions:

Remarks

This function automatically idles the CPU when required so that it can be safely used in tight loops without hogging all the CPU.

Adding a Sleep just makes the whole loop very unresponsive - as mexykanu found. :-)

M23

[weirddave]

Interesting, I must admit, I'm not too familiar with GUI and Tray functions. I find a small sleep does often help stop loops hogging the cpu tho even if it's just 1ms to keep it nice and responsive. Obviously not much help in this case....