tray application that show popup GUI - need help

[fizyk]

Hi,

I'm trying to prepare tray application that show popup GUI. Problem is with event that shows/hides popup GUI. I don't know how to show popup GUI when cursor is on tray icon and how to hide it when cursor is out of tray icon.

I used "$TRAY_EVENT_MOUSEOVER" it shows popup but I can't hide it automaticaly.

Please help....

[fizyk]

anybody???

[BJJ]

maybe make hide to tray by hotkey

[fizyk]

maybe make hide to tray by hotkey

I want do some automatic popup. When I put mouse cursor on tray icon it shows up when I take off mouse it dispersers.

[Melba23]

fizyk,

Firstly, do not bump a post within 24 hours again. These forums are not a 24/7 tech support - if someone can help you they will, but you need to be patient. If you are not....you will get no help! :-)

But you do get help this time. I think this is what you are looking for - the GUI appears when your cursor is over the icon and vanishes when you move away:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#Include <GuiToolBar.au3>

Global $aIcon[4]
Find_Icon()

$hWin = GUICreate("Test", 100, 100)
GUISetState(@SW_HIDE, $hWin)

$fShowing = False

While 1
    
    If GUIGetMsg() = -3 Then Exit
    
    $aMouse = MouseGetPos()
    
    If $aMouse[0] >= $aIcon[0] And $aMouse[0] <= $aIcon[2] And $aMouse[1] >= $aIcon[1] And $aMouse <= $aIcon[3] Then
    ; Over icon
        If $fShowing = False Then
            $fShowing = True
            GUISetState(@SW_SHOW, $hWin)
            ConsoleWrite("Showing" & @CRLF)
        EndIf
        
    Else
    ; Off icon
        If $fShowing Then
            ConsoleWrite("Hidden" & @CRLF)
            GUISetState(@SW_HIDE, $hWin)
            $fShowing = False
        EndIf
    EndIf
    
WEnd


Func Find_Icon()

; Find systray handle
$SysTray_Handle = ControlGetHandle('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
If @error Then
    MsgBox(16, "Error", "System tray not found")
    Exit
EndIf

; Get systray item count
$Systray_ButCount = _GUICtrlToolbar_ButtonCount($SysTray_Handle)
If $Systray_ButCount = 0 Then
    MsgBox(16, "Error", "No items found in system tray")
    Exit
EndIf

; Look for tooltip
$Tool_Tip = ""
For $Systray_ButtonNumber = 0 To $Systray_ButCount - 1
; Need to change "AutoIt" to name of your exe when compiled
    $Test = StringSplit(_GUICtrlToolbar_GetButtonText($SysTray_Handle, $Systray_ButtonNumber), "AutoIt" ,1)
    If $Test[0] <> 1 Then ExitLoop
Next

If $Systray_ButtonNumber = $Systray_ButCount Then
; Icon not found
    MsgBox(16, "Error", "AutoIt icon not found in system tray")
    Exit
Else
; Get absolute coords of icon
; get icon size
    $aIcon = _GUICtrlToolbar_GetButtonRect($SysTray_Handle, $Systray_ButtonNumber)
; get x coord of systray
    $aSysTray = ControlGetPos('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
    $aIcon[0] = $aSysTray[0]
    $aIcon[2] = $aSysTray[0] + $aIcon[2]
; get y coord of taskbar
    $aTaskBar = WinGetPos('[Class:Shell_TrayWnd]', '')
    $aIcon[1] = $aTaskBar[1]
    $aIcon[3] = $aTaskBar[1] + $aIcon[3]
EndIf

EndFunc

Please ask if there is anything you do not understand.

M23

[fizyk]

Thank you very much. That is what I looking for...

Edited February 5, 2009 by fizyk