check for valid file name while entering text

[rudi]

Hi.

I'm 100% sure, that there is some posting with a nice sample code, that uses some GUI with a GUICtrlCreateInput(), and that checks the entered string for not allowed characters for file names. If such a Char was entered, the previous content is restored. By that it was impossible to enter invalid Chars.

I cannot find it.

Who, please, can open my blind eyes?

Regards, Rudi.

[Authenticity]

File name cannot contain this characters "\/:*?"<>|" so using StringRegExp($sFile, '[\\/:*?"<>|]) will return true to indicate a non-valid file name in this case, most of the quantifiers or metacharacters don't retain their special meaning withing a class so use \Q...\E if you're not sure.

Same for the path\filename.exe:

Dim $aFile = StringRegExp($sFile, '(.*\\)(.*)', 3)

Results in an array with two elements if it's a valid path or 1 or non-array if it's not a valid file string. The rest is to check whether the file exists.

Edit: My bad... search for subclassing of the control's message loop and assign yours and return the rest unhandled events to the previous or original message loop of the control.

Edited February 20, 2009 by Authenticity

[GEOSoft]

I forget the list of invalid Characters but all you have to do is check the last character of the input against the list and if it exists in the list then use GUICtrlSetData() to trim that character.

$sNotAllowed = "?\;"

While 1
    $sCurrentChar = StringRight(GUICtrlRead($input), 1)
    If StringInStr($sNotAllowed, $sCurrentChar) Then GUICtrlSetData($input, StringTrimRight(GUICtrlRead($input), 1))
Wend

Edited February 20, 2009 by GEOSoft

[Authenticity]

#include <Constants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)


Dim $hUser32 = DllOpen('user32.dll')
Dim $hGUI = GUICreate ('Title', 200, 100)
Dim $Input = GUICtrlCreateInput ('', 0, 0, 200, 100)
Dim $hInput_Handler = DllCallbackRegister ('Input_Handler', 'lparam', 'hwnd;uint;wparam;lparam')
    If 0 = $hInput_Handler Then Exit

Dim $hOldProc = _WinAPI_GetWindowLong (GUICtrlGetHandle($Input), $GWL_WNDPROC)
_WinAPI_SetWindowLong (GUICtrlGetHandle($Input), $GWL_WNDPROC, DllCallbackGetPtr($hInput_Handler))

GUISetState()

Do
    Sleep (20)
Until GUIGetMsg() = -3


GUIDelete($hGUI)
DllCallbackFree($hInput_Handler)
DllClose($hUser32)
Exit


Func Input_Handler($hWnd, $uMsg, $wParam, $lParam)
    If $uMsg = $WM_CHAR Then
        If StringRegExp(Chr($wParam), '[\Q\/:*?"<>|\E]') Then Return 0
    EndIf
    
    Local $Ret = DllCall($hUser32, 'int', 'CallWindowProc', 'ptr', $hOldProc, 'hwnd', $hWnd, 'uint', $uMsg, 'wparam', $wParam, 'lparam', $lParam)
    If Not @error Then Return $Ret[0]
EndFunc

You can modify it to get the window text of $hWnd to restore the old text or...

[rudi]

Hi.

I will have a closer look to your code right now.

What I've seen was about this, but *MUCH* better code:

[edit] I think it was just 15 lines, about... [/edit]

expandcollapse popup

#include <guiconstantsEx.au3>
; ['<', '>', '|', '"', '\', '/', ':', '*', '?']

$w = 200
$h = 100
$MyGui = GUICreate("Enter valid file name", $w, $h)
$input = GUICtrlCreateInput("", 20, 20, $w - 40, 20)
$button = GUICtrlCreateButton("Done", 20, 70)
GUISetState(@SW_SHOW)

$start = TimerInit()
While 1
    $WinPos = WinGetPos($MyGui)
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            If GUICtrlRead($input) = "" Then
                MsgBox(48, "Nothing entered", "Empty file names are *NOT* allowed")
            Else
                ExitLoop
            EndIf
        Case $msg = $button
            If GUICtrlRead($input) = "" Then
                MsgBox(48, "Nothing entered", "Empty file names are *NOT* allowed")
            Else
                ExitLoop
            EndIf
    EndSelect
    $String = GUICtrlRead($input)
    $valid = StringRegExpReplace($String, "[\[\]/\|\:\?""\*\\<>]", "")
    If Not ($valid = $String) Then
        $start = TimerInit()
        ToolTip("Not allowed Characters: '<', '>', '|', '""', '\', '/', ':', '*', '?'", $WinPos[0], $WinPos[1] + 70)
    EndIf
    GUICtrlSetData($input, $valid)
    If TimerDiff($start) > 2000 Then ToolTip("")
    Sleep(10)
WEnd

$final = GUICtrlRead($input)
GUIDelete()

MsgBox(0, "Valid Filename:", $final)

Regards, Rudi.

Edited February 20, 2009 by rudi

[rudi]

StringRegExp(Chr($wParam), '[\Q\/:*?"<>|\E]')

Ah! I didn't know this "\Q" ...."\E" to "bulk escape" a string. Very nice!

The rest I will have to dig though step by step.

Thanks, Rudi.

[rudi]

Hi.

I forget the list of invalid Characters ...

It's these: '<', '>', '|', '"', '\', '/', ':', '*', '?'

Thanks, regards, Rudi.

[Ascend4nt]

One thing to consider: '/' is translated by Windows functions to '\', so if anything contains a path keep that in mind.

Also invalid for files/foldernames are whitespace before or after a filename (it's okay between). But to test that in real-time wouldn't work.

[Authenticity]

This is for the FileExist function. The rest deal with what is not valid for a filename, file path can contain \ or it must lol so filtering it was taken as consideration that the input box meant to hold only valid file names. Whether the input box contain a space in front of the text? it's for the FileExist to test it.

[rudi]

Also invalid for files/foldernames are whitespace before or after a filename (it's okay between).

Sorry, but that's nonsense:

LEADING whitspaces are fine for Windows.

TRAILING whitespaces simply are truncated.

Check yourself:

--------- whitespacechecker.cmd------------
@echo off
echo. > "     with spaces   . txt   "
for %%a in (*with*) do echo "%%a"
------------------ EOF -------------------------

But to test that in real-time wouldn't work.

Why not? StringRegExp is offering the matches "^\s" and "\s$", but I can't see the need for it?

Regards, Rudi.

[Authenticity]

....

LEADING whitspaces are fine for Windows.

TRAILING whitespaces simply are truncated.

...

Actually, the opposite is the correct one:

" some.txt" is truncated to "some.txt" while,

"some.txt " remains "some.txt "

[Ascend4nt]

Sorry, but that's nonsense:

LEADING whitspaces are fine for Windows.

TRAILING whitespaces simply are truncated.

...

Regards, Rudi.

For *filenames*, yes, TRAILING whitespace is okay. NO leading whitespace is okay though.

If Not FileExists(@ScriptDir & '\ ' & @ScriptName) Then ConsoleWriteError('"' & @ScriptDir & '\ ' & @ScriptName & '" does NOT exist' & @CRLF)

For FOLDERnames *within* a path, BOTH are not okay, but since we are only dealing with filenames, you don't have to deal with that.

*also, testing for trailing whitespace in realtime is not possible, as there can be spaces within folder\filenames

Edited February 21, 2009 by ascendant

[rudi]

Actually, the opposite is the correct one:

" some.txt" is truncated to "some.txt" while,

"some.txt " remains "some.txt "

Pls save my sample CMD batch file, open a CMD box, run it and see, what I mean

Regards, Rudi.

[Ascend4nt]

Okay, I gave it a test with DirCreate() and FileWrite(), and you're right - It *does* allow leading whitespace.

It doesn't allow it when you create something through Explorer though - that's probably where I got my mistaken belief from.

Anyway, thanks for enlightening me

[ResNullius]

Hi.

I will have a closer look to your code right now.

What I've seen was about this, but *MUCH* better code:

[edit] I think it was just 15 lines, about... [/edit]

Was it this?

http://www.autoitscript.com/forum/index.ph...st&p=354577

[rudi]

Was it this?

http://www.autoitscript.com/forum/index.ph...st&p=354577

Exactly that one! Thanks, Rudi.

[Funtime60]

On 2/20/2009 at 4:38 PM, Ascend4nt said:

One thing to consider: '/' is translated by Windows functions to '\', so if anything contains a path keep that in mind.

This isn't always correct, using /  as the initial directory in FileOpenDialog and FileSaveDialog will cause it to browse to usually the last directory that was opened by the program in this manner, at least in my experience. This may be Autoit's fault though.