Script iniWrite problem

[shyron]

I want to Choose e.g. MSN.exe, that works fine, but my problem is, when starting the script the 2. time I'd have to choose the path again even if it would be the same. How could i change that?(By saving yea, well heres my try)

If iniRead ("config", "Config", "msn", "") = "" Then
 FileOpenDialog ( "msn", "C:/", ".exe (*.*)" ,"" , "msn")
$sbot = iniWrite ("config", "config", "msn", "msn")
else 
 iniRead ("config", "Config", "msn", "") = $msn
EndIf

[SpookMeister]

It will depend on how you want to integrate it with the rest of your code. Pay attention to what you get in the way of returns from IniRead... I'll throw something together as an example for you in a few.

[shyron]

EDIT: I GOT IT

Edited February 22, 2009 by shyron

[SpookMeister]

Cool... here is my example anyway:

#include <GUIConstantsEx.au3>

Local $msg , $iniPath = @ScriptDir & "\settings.ini"
GUICreate("My GUI combo") ; will create a dialog box that when displayed is centered

$combo=GUICtrlCreateCombo("AOL", 10, 10) ; create first item
GUICtrlSetData($combo, "Google|MSN", "Google") ; add other item snd set a new default
GUISetState()

; grab the settings from the ini file, or make it if it is the first time
If FileExists($iniPath) Then
    $provider=IniRead($iniPath,"Settings","Provider","MSN")
    GUICtrlSetData($combo,$provider)
Else
    IniWrite($iniPath,"Settings","Provider","MSN")
EndIf
; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

; write the current setting to the ini file
IniWrite($iniPath,"Settings","Provider",GUICtrlRead ($combo))

[Ealric]

$ini = @ScriptDir & "\config.ini" ; path from script default directory to the config.ini
IniReadSection($ini, "Config") ; try to read the Config section
If @error Then ; section doesn't exist so create it
    IniWriteSection($ini, "Config", "config=0") ; write the section but leave the path set to 0 so it can be set later.
EndIf
If IniRead($ini,"Config","config","") <> 0 Then ; if the script doesn't see 0 then you can move onward
    ;Input what you want to do if everything is OK with the ini file here.
Else
    Local $fOpen = FileOpenDialog("msn","C:\",".exe (*.*)","","msn") ; open the msn.exe file (prompt for dialog)
    IniWrite($ini,"Config","config",$fOpen) ; write the full path the msn.exe file here and use it going forward.
EndIf
Global $msn = IniRead($ini,"Config","config","")
MsgBox(0,"Reading .ini","My msn var is set to " & $msn)