How to remove a style?

[AlmarM]

Hello,

I was wondering, how to remove a style from a control?

This doesn't seem to work.

#include <EditConstants.au3>

$GUI = GUICreate("Example", 300, 100)
$Input = GUICtrlCreateInput(Random(0, 9, 1) & Random(0, 9, 1) & Random(0, 9, 1) & Random(0, 9, 1), 10, 10, 280, 20, $ES_CENTER + $ES_PASSWORD)
$HideShow = GUICtrlCreateButton("Show", 127, 40, 50)

GUICtrlSetLimit($Input, 4, 0)
GUISetState()
While 1
    $nMsg = GUIGetMsg()
    Select
    Case $nMsg = -3
        Exit
    Case $nMsg = $HideShow
        If GUICtrlRead($HideShow) = "Show" Then
            GUICtrlSetStyle($Input, $ES_CENTER)
            GUICtrlSetData($HideShow, "Hide")
        Else
            GUICtrlSetStyle($Input, $ES_CENTER + $ES_PASSWORD)
            GUICtrlSetData($HideShow, "Show")
        EndIf
    EndSelect
WEnd

AlmarM

Edited March 17, 2009 by AlmarM

[Authenticity]

Some styles are not changeable, you can use this for example:

_WinAPI_SetWindowLong($hWnd, $GWL_STYLE, BitXOR(_WinAPI_GetWindowLong($hWnd, $GWL_STYLE), $WS_VISIBLE))

To hide the window if it's visible and vice versa but if this style cannot be changed on run-time then it won't work.

[jvanegmond]

You should actually BitOR the styles together instead of adding them.

[AlmarM]

So how can I remove the $ES_PASSWORD in my example?

AlmarM

[Authenticity]

ANDing anything with not $ES_PASSWORD.

$ES_PASSWORD = 32

_WinAPI_SetWindowLong($hWnd, $GWL_STYLE, BitAND(_WinAPI_GetWindowLong($hWnd, $GWL_STYLE), _
                 BitXOR($ES_PASSWORD, 0xFFFFFFFF)))

But I think the this style is unchangeable on run-time.

Edited March 17, 2009 by Authenticity

[AlmarM]

Yep, I think its unchangeable.

#Include <WinAPI.au3>
#include <EditConstants.au3>
#include <Constants.au3>

$GUI = GUICreate("Example", 300, 100)
$Input = GUICtrlCreateInput(Random(0, 9, 1) & Random(0, 9, 1) & Random(0, 9, 1) & Random(0, 9, 1), 10, 10, 280, 20, $ES_CENTER + $ES_PASSWORD)
$HideShow = GUICtrlCreateButton("Show", 127, 40, 50)

GUICtrlSetLimit($Input, 4, 0)
GUISetState()
While 1
    $nMsg = GUIGetMsg()
    Select
    Case $nMsg = -3
        Exit
    Case $nMsg = $HideShow
        If GUICtrlRead($HideShow) = "Show" Then
            _WinAPI_SetWindowLong($GUI, $GWL_STYLE, BitAND(_WinAPI_GetWindowLong($GUI, $GWL_STYLE), BitXOR($ES_PASSWORD, 0xFFFFFFFF)))
            GUICtrlSetData($HideShow, "Hide")
        Else
            GUICtrlSetStyle($Input, $ES_CENTER + $ES_PASSWORD)
            GUICtrlSetData($HideShow, "Show")
        EndIf
    EndSelect
WEnd

AlmarM

Edited March 17, 2009 by AlmarM

[Authenticity]

You should change the $hEdit and not the $hGUI style.

..
.
.

Case $nMsg = $HideShow
      $hEdit = GuiCtrlGetHandle($Input)
      WinAPI_SetWindowLong($hEdit, $GWL_STYLE, BitAND(_WinAPI_GetWindowLong($hEdit, $GWL_STYLE),
              BitXOR($ES_PASSWORD, 0xFFFFFFFF)))
..
.
.

Then, confirm if it doesn't work.

[MrCreatoR]

Try this:

expandcollapse popup

#include <EditConstants.au3>
#include <Constants.au3>
;

$GUI = GUICreate("Example", 300, 100)

$Input = GUICtrlCreateInput(Random(0, 9, 1) & Random(0, 9, 1) & Random(0, 9, 1) & Random(0, 9, 1), 10, 10, 280, 20, $ES_CENTER)
GUICtrlSetLimit($Input, 4, 0)

$HideShow = GUICtrlCreateButton("Show", 127, 40, 50)

_GUICtrlEdit_TogglePassChars($GUI, $Input, 1, Chr(149))

GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $HideShow
            If GUICtrlRead($HideShow) = "Show" Then
                _GUICtrlEdit_TogglePassChars($GUI, $Input, 0)
                GUICtrlSetData($HideShow, "Hide")
            Else
                _GUICtrlEdit_TogglePassChars($GUI, $Input, 1, Chr(149))
                GUICtrlSetData($HideShow, "Show")
            EndIf
    EndSwitch
WEnd

Func _GUICtrlEdit_TogglePassChars($hWnd, $hCtrl, $iToggleState = -1, $sPassChar = "*")
    If Not IsHWnd($hWnd) Then $hWnd = WinGetHandle($hWnd)
    If Not IsHWnd($hCtrl) Then $hCtrl = ControlGetHandle($hWnd, "", $hCtrl)
    
    Local Const $EM_SETPASSWORDCHAR = 0xCC
    Local Const $EM_GETPASSWORDCHAR = 0xD2
    
    Local $iPass_Char = 0
    Local $aRet = DllCall("user32.dll", "long", "SendMessage", "hwnd", $hCtrl, "int", $EM_GETPASSWORDCHAR, "int", 0, "int", 0)
    If IsArray($aRet) And Not $aRet[0] Then $iPass_Char = Asc($sPassChar)
    If $iToggleState = 0 Then $iPass_Char = 0
    DllCall("user32.dll", "long", "SendMessage", "hwnd", $hCtrl, "int", $EM_SETPASSWORDCHAR, "int", $iPass_Char, "int", 0)
    
    ControlFocus($hWnd, "", $hCtrl)
EndFunc

[AlmarM]

Thx MrCreatoR!

AlmarM