Listview subitem select

[Cyri]

I'm working with a listview with report view style on. I'm wondering if there's a way to select sub-items? No matter how I configure it I can either select the entire row or only the main items. Hoping someone may know of a way to do this.

[martin]

I'm working with a listview with report view style on. I'm wondering if there's a way to select sub-items? No matter how I configure it I can either select the entire row or only the main items. Hoping someone may know of a way to do this.

Add this line after creating your listview

GUIRegisterMsg($WM_NOTIFY, "WM_Notify_Events")

and add this function

Func WM_Notify_Events($hWndGUI, $MsgID, $wParam, $lParam)
        #forceref $hWndGUI, $MsgID, $wParam
        Local $tagNMHDR, $event,$selrow,$selcol
        $tagNMHDR = DllStructCreate("int;int;int", $lParam);NMHDR (hwndFrom, idFrom, code)
        If @error Then Return
        $event = DllStructGetData($tagNMHDR, 3)
        Select
            Case $wParam = $ListView1;<----------change to be the variable for your listview

                Select
                    Case $event = $NM_CLICK;<--------assuming you want to know the column when you left click
                        Local $tagNMITEMACTIVATE = DllStructCreate("int;int;int;int;int;int;int;int;int", $lParam)
                        $selrow = DllStructGetData($tagNMITEMACTIVATE, 4)
                        $selcol = DllStructGetData($tagNMITEMACTIVATE, 5)

                        ConsoleWrite("col selected = " & $selcol & @CRLF);<-------replace with your own code           
                    
                EndSelect
        EndSelect

        Return $GUI_RUNDEFMSG
EndFunc  ;==>WM_Notify_Events

[npploveyou]

sorry to dig up this old topic but when I was searching for the same concept, I found this interesting page.

So please just help with my question, instead of single click to view the sub item, how to change it to double click?

Single click is cool but if I make the event to let people open a website when click on the column, that would be mess! The better way that I could think of is change it to double mouse click.

Thanks!

[twitchyliquid64]

You need to detect double clicks manually, using guigetmsg, timers, and counters.

So you detect clicks on the control, and then check which is selected.

[Melba23]

hyperzap,

You need to detect double clicks manually, using guigetmsg, timers, and counters

Sorry to be blunt, but that is complete rubbish.

You just need to look for the $NM_DBLCLK message and enlarge the struct to give you the column value as well.

npploveyou,

Here is an example showing how to do it - look for the <<<<<<<<<<< lines:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListView.au3>

$hGui = GUICreate("Test", 250, 250)

$hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3", 10, 10, 230, 160)
For $i = 1 To 6
    GUICtrlCreateListViewItem("Item " & $i & "1|Item " & $i & "2|Item " & $i & "3", $hListView)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam

    Local $tStruct = DllStructCreate("hwnd;uint_ptr;int_ptr;int;int", $lParam) ; Increase the struct size to get the column <<<<<<<<<<<<<<<<
    If @error Then Return
    Switch DllStructGetData($tStruct, 3)
        Case $NM_DBLCLK ; Look for the double click <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            ConsoleWrite("Row: " & DllStructGetData($tStruct, 4) + 1 & " - Col: " &DllStructGetData($tStruct, 5) + 1 & @CRLF)
    EndSwitch

EndFunc   ;==>On_WM_NOTIFY

All clear?

M23

[npploveyou]

that was perfectly clear for me.

Thanks a lot!