convert text file from [ANSI UNIX] to [ANSI PC]

[myspacee]

hello to all,

I need to open a [ANSI UNIX] text file and save in [ANSI PC] format,

is possible with Autoit without use external tool ?

thank you,

m.

[Richard Robertson]

What do you mean by UNIX and PC? Are you referring to the line endings?

That's easy. Just read each character and if you find a line feed, add a carriage return.

[GEOSoft]

hello to all,

I need to open a [ANSI UNIX] text file and save in [ANSI PC] format,

is possible with Autoit without use external tool ?

thank you,

m.

If it's just the line feed difference then you could use a simple StringReplace.

$sStr = FileRead("C:\some\text\file.txt")
$sStr = StringReplace($sStr, @LF, @CRLF)

EDIT:

Actually, better yet

$sStr = StringStripCR(FileRead("C:\some\text\file.txt"))
$sStr = StringReplace($sStr, @LF, @CRLF)

Edited March 20, 2009 by GEOSoft

[GEOSoft]

Now you have me thinking. I'm thinking that what I gave you is actually Mac to Windows.

If that doesn't work then try this one.

$sStr = FileRead("C:\some\text\file.txt")
$sStr = StringReplace($sStr, @LF, "")
$sStr = StringReplace($sStr, @CR, @CRLF)

All of these are untested by the way

[ProgAndy]

the linefeeds: ( http://en.wikipedia.org/wiki/Newline )

* LF:   Multics, Unix and Unix-like systems (GNU/Linux, AIX, Xenix, Mac OS X, FreeBSD, etc.), BeOS, Amiga, RISC OS, and others
    * CR+LF: DEC RT-11 and most other early non-Unix, non-IBM OSes, CP/M, MP/M, DOS, OS/2, Microsoft Windows, Symbian OS
    * CR:   Commodore machines, Apple II family, Mac OS up to version 9 and OS-9

So this should convert all:

Enum $NL_MAC, $NL_WIN, $NL_NIX
Func _NewlineConv($text, $type=$NL_WIN)
; Prog@ndy
    Switch $type
        Case $NL_WIN
            If StringInStr($text,@LF) Then
                Return StringReplace(StringStripCR($text),@LF,@CRLF)
            Else
                Return StringReplace($text,@CR,@CRLF)
            EndIf
        Case $NL_MAC
            If StringInStr($text,@LF) Then
                Return StringReplace(StringStripCR($text),@LF,@CR)
            Else
                Return $text
            EndIf
        Case $NL_NIX
            If StringInStr($text,@LF) Then
                Return StringStripCR($text)
            Else
                Return StringReplace($text,@CR,@LF)
            EndIf
        Case Else
            Return SetError(1,0,$text)
    EndSwitch
EndFunc

Edited March 20, 2009 by ProgAndy

[myspacee]

this resolve:

$sStr = FileRead("C:\some\text\file.txt")
$sStr = StringReplace($sStr, @LF, "")
$sStr = StringReplace($sStr, @CR, @CRLF)

thank you all,

m.