output in big format

[mentosan]

Hi !

Is it possible to change the format of MsgBox() into big letters font ? Or is there a way to ouput the return message from a script into big characters in the same way how Windows shows "1" or "2" when checking identification in display properties ?

Thank you

[Authenticity]

You can't change the MsgBox font size, you can make your own MsgBox though. What do you mean the return message from a script? Strings have nothing to do with fonts or attributes, it's the control that suppose to show them in the different fonts and fonts-size.

[mentosan]

You can't change the MsgBox font size, you can make your own MsgBox though. What do you mean the return message from a script? Strings have nothing to do with fonts or attributes, it's the control that suppose to show them in the different fonts and fonts-size.

My script will return a value. I want this value to be displayed in bigger font-size.

[BrettF]

http://www.autoitscript.com/forum/index.php?showtopic=72294?

[ResNullius]

Or is there a way to ouput the return message from a script into big characters in the same way how Windows shows "1" or "2" when checking identification in display properties ?

... or this, originally by Larry:

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

$hwnd = GUICreate("Text Region",400,50,-1,-1,$WS_POPUP,BitOR($WS_EX_TOPMOST,$WS_EX_TOOLWINDOW))
GUISetBkColor(0x00FF00)

$rgn = CreateTextRgn($hwnd,"Larry Rocks!",50,"Arial",1000)
SetWindowRgn($hwnd,$rgn)

GUISetState()

Sleep(3000)

$rgn = CreateTextRgn($hwnd,"Really Really",50,"Arial",1000)
SetWindowRgn($hwnd,$rgn)

Sleep(3000)

Func SetWindowRgn($h_win, $rgn)
    DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $rgn, "int", 1)
EndFunc

Func CreateTextRgn(ByRef $CTR_hwnd,$CTR_Text,$CTR_height,$CTR_font="Microsoft Sans Serif",$CTR_weight=1000)
    Local Const $ANSI_CHARSET = 0
    Local Const $OUT_CHARACTER_PRECIS = 2
    Local Const $CLIP_DEFAULT_PRECIS = 0
    Local Const $PROOF_QUALITY = 2
    Local Const $FIXED_PITCH = 1
    Local Const $RGN_XOR = 3

    If $CTR_font = "" Then $CTR_font = "Microsoft Sans Serif"
    If $CTR_weight = -1 Then $CTR_weight = 1000
    Local $gdi_dll = DLLOpen("gdi32.dll")
    Local $CTR_hDC= DLLCall("user32.dll","int","GetDC","hwnd",$CTR_hwnd)
    Local $CTR_hMyFont = DLLCall($gdi_dll,"hwnd","CreateFont","int",$CTR_height,"int",0,"int",0,"int",0, _
                "int",$CTR_weight,"int",0,"int",0,"int",0,"int",$ANSI_CHARSET,"int",$OUT_CHARACTER_PRECIS, _
                "int",$CLIP_DEFAULT_PRECIS,"int",$PROOF_QUALITY,"int",$FIXED_PITCH,"str",$CTR_font )
    Local $CTR_hOldFont = DLLCall($gdi_dll,"hwnd","SelectObject","int",$CTR_hDC[0],"hwnd",$CTR_hMyFont[0])
    DLLCall($gdi_dll,"int","BeginPath","int",$CTR_hDC[0])
    DLLCall($gdi_dll,"int","TextOut","int",$CTR_hDC[0],"int",0,"int",0,"str",$CTR_Text,"int",StringLen($CTR_Text))
    DLLCall($gdi_dll,"int","EndPath","int",$CTR_hDC[0])
    Local $CTR_hRgn1 = DLLCall($gdi_dll,"hwnd","PathToRegion","int",$CTR_hDC[0])
    Local $CTR_rc = DLLStructCreate("int;int;int;int")
    DLLCall($gdi_dll,"int","GetRgnBox","hwnd",$CTR_hRgn1[0],"ptr",DllStructGetPtr($CTR_rc))
    Local $CTR_hRgn2 = DLLCall($gdi_dll,"hwnd","CreateRectRgnIndirect","ptr",DllStructGetPtr($CTR_rc))
    DLLCall($gdi_dll,"int","CombineRgn","hwnd",$CTR_hRgn2[0],"hwnd",$CTR_hRgn2[0],"hwnd",$CTR_hRgn1[0],"int",$RGN_XOR)
    DLLCall($gdi_dll,"int","DeleteObject","hwnd",$CTR_hRgn1[0])
    DLLCall("user32.dll","int","ReleaseDC","hwnd",$CTR_hwnd,"int",$CTR_hDC[0])
    DLLCall($gdi_dll,"int","SelectObject","int",$CTR_hDC[0],"hwnd",$CTR_hOldFont[0])
    DLLClose($gdi_dll)
    Return $CTR_hRgn2[0]
EndFunc

Edited March 24, 2009 by ResNullius

[mentosan]

Niiiiice !

Thank you very much !