text as array index ... possible?

[Zephir]

Hey guys,

is there a way to use strings (or lets say anything but numbers) as an array index?

e.g.

$array["Name"] = Zephir

i tried a few things and it always promts me with an error... help file does not help either

thank you

Zephir

[Melba23]

Zephir,

I cannot imagine why you would want to use anything other than numbers as array indices.... but this is as close as I can get to using strings:

Global $aArray[2] = ["One", "Two"]

$First = 0
$Second = 1

ConsoleWrite($aArray[Eval("First")] & @CRLF)
ConsoleWrite($aArray[Eval("Second")] & @CRLF)

M23

[Zephir]

thanks M23 you gave me a good idea. gonna try it.

i'm working on a script that has quite big arrays... and im tired of getting confused by numbers... words would explain the value of the element and make things a lot easier

Zephir

[weaponx]

; Create dictionary object
Dim $oDictionary = ObjCreate("Scripting.Dictionary")
$oDictionary("var1") = "something"
$oDictionary("var2") = "something else"

MsgBox(0,"",$oDictionary("var1"))

[jchd]

is there a way to use strings (or lets say anything but numbers) as an array index?

$array["Name"] = Zephir

What you're after is unclear. Your code is also unclear: what is Zephyr supposed to be? The syntax is bad anyway.

If you need to find a string value in an array, use _ArraySearch.

If you intend to access array members by a more mnemonic way than numbers, try defining constants (lookup Enum).

If you need an association between a string ("Name") and a value ($Zephyr or "Zephyr") then you need a 2D array. The bad news is that AutoIt arrays aren't natively associative, but the good one is that you can easily get the same behavior. Note that if your array is big you might think about using SQLite instead.

#include <array.au3>

Local $array[6][2] = [["Fred",  "guru"], _
                ["Paul",    "newbie"], _
                ["Jane",    "geek"], _
                ["Alan",    "user"], _
                ["Suzan",   "spy"], _
                ["Eric",    "developper"]   ]
Local $index
Local $value

$index = _ArraySearch($array, "Jane")
$value = $array[$index][1]  ;; this gets "geek"
MsgBox(0,"Jane is a",$value)

[jchd]

i'm working on a script that has quite big arrays... and im tired of getting confused by numbers... words would explain the value of the element and make things a lot easier

Now I understand much better what you need.

Use Enum to define your constants then use them directly:

Global Enum $_firstname, $_familyname, $_adrs1, $_adrs2, $_city, $_zip, $_state, $_country, $_email

Local $array[1][9] = [["Fred", "Stone", "1450 AutoIt Avenue", "", "Paris", "78563", "TEXAS", "USA", "fred.stone@autoit.net"]]
Local $zip1, $zip2

;; now you can access ZIP code with either colomn number or colomn name
$zip1 = $array[0][5]
$zip2 = $array[0][$_zip]

MsgBox(0, "Access successful ?", $zip1 = $zip2)

[Zephir]

Now I understand much better what you need.

Use Enum to define your constants then use them directly:

Global Enum $_firstname, $_familyname, $_adrs1, $_adrs2, $_city, $_zip, $_state, $_country, $_email

Local $array[1][9] = [["Fred", "Stone", "1450 AutoIt Avenue", "", "Paris", "78563", "TEXAS", "USA", "fred.stone@autoit.net"]]
Local $zip1, $zip2

;; now you can access ZIP code with either colomn number or colomn name
$zip1 = $array[0][5]
$zip2 = $array[0][$_zip]

MsgBox(0, "Access successful ?", $zip1 = $zip2)

that is exactly what i was looking for thanks a lot ichd!

sorry that my explanation was so missleading

Zephir

[DaleHohm]

Search the forum for aGorilla's HASH.au3 UDF... this is exactly what it is for.

Dale

[Melba23]

All,

Thanks for the illuminating replies - always good to learn new tricks.

M23

[Zephir]

this is the best community ever

thanks a lot!