removing duplicates in a string

[7121]

basically i have this

$Ran = Random(1, 9 )

Which btw, does anyone know how to make random like a huge number, without FLOAT??? o_0

okay, after that,

$Ran = $Ran*123456789
$Ran = Int ($Ran)

easiest way i know to make a huge RANDOM number as an integer =/

Now the problem is i don't want duplicates .

example:

11, 2222, 33333333, 444,

basically i only want 1712938125, each number is different on every next digit. I think it's really easy but somehow i'm not figuring it out and i go with manual of StringReplace... like LOTS of them, about 20 of them, hoping the duplicate won't show up.

[Melba23]

7121,

Random will deal with numbers up to 2^31 (that is up to 2,147,483,647) - I think that counts as 'huge'. Setting the 'Flag' parameter will return integers - so that is the first question dealt with!

Now to the 'duplicate' problem - as you do not want successive integers to be the same, we are already outside any real defintion of "random", so why not just amend the numbers so they no longer match? Although I feel we should make at least a token effort by increasing or decreasing them at random! :-):

;  Get large integer
$sInt = String(Random(1000000, 10000000, 1))
; Split into elements
$aInt = StringSplit($sInt, "")
; Increase/decrease elements randomly if they match preceding element
For $i = 1 To $aInt[0] - 1
    If $aInt[$i + 1] = $aInt[$i] Then
        $iUpDown = Random(0, 1)
        If $iUpDown > .5 Then
            $aInt[$i + 1] += 1
            If $aInt[$i + 1] = 10 Then $aInt[$i + 1] = 0
        Else
            $aInt[$i + 1] -= 1
            If $aInt[$i + 1] = -1 Then $aInt[$i + 1] = 9
        EndIf
    EndIf
Next
; Recreate number
$sInt = ""
For $i = 1 To $aInt[0]
    $sInt &= $aInt[$i]
Next
$iInt = Int(Number($sInt))
; Display it
ConsoleWrite($iInt & @CRLF)

M23

[TheSaint]

basically i have this

Now the problem is i don't want duplicates .

example:

11, 2222, 33333333, 444,

basically i only want 1712938125, each number is different on every next digit. I think it's really easy but somehow i'm not figuring it out and i go with manual of StringReplace... like LOTS of them, about 20 of them, hoping the duplicate won't show up.

I'd go with StringMid and count your way through the number, and keep incrementing so that next number doesn't match last, so that

11, 2222, 33333333, 444,

would become

12, 3232, 34343434, 545,

if you just incremented by 1 each time.

If you vary the increment each time, then you would get a less uniform number.

[jchd]

Now the problem is i don't want duplicates .

example:

11, 2222, 33333333, 444,

basically i only want 1712938125, each number is different on every next digit. I think it's really easy but somehow i'm not figuring it out and i go with manual of StringReplace... like LOTS of them, about 20 of them, hoping the duplicate won't show up.

There are plenty of high quality proven random number generators floating around, just google. BTW, discarding 33333 is definitely not a good idea. 33333 is as random as 57404583 can be. It "just" happen to have a decimal expression that makes it easy to spot. Express your numbers in hex and you'll find a completely different set of "not looking random" numbers. Then try octal or binary or ... Even duplicates in 2^32 are "normal" (I won't go into a mathematical discussion about what that means).

Duplicates might be unsuited to your precise application, but they are nothing else than "normal". Not finding any would be a _big_ security breach! Think about it: roll a dice and apply your paradigm: if you got 3 then you must get something else! Roll the dice 5 times and --if dups are banned-- I for one that can predict which shall be the next number. This is clearly getting more and more predictable (the contrary to random) as the number of values already appeared increase and tend towards the number of possibilities.

[Xenobiologist]

ConsoleWrite(_randomNr(10) & @CRLF)

Func _randomNr($length = 1)
    Local $nr = Random(0, 9, 1), $tmp = ''
    While StringLen($nr) < $length
        $tmp = Random(0, 9, 1)
        If $tmp <> StringRight($nr, 1) Then $nr &= $tmp
    WEnd
    Return $nr
EndFunc  ;==>_randomNr

Mega

[7121]

thank you very much guys... even though i'm still a little confused but i'll figure it out