How to detect if existing program is aleady running

[JohnRichard]

hi to all. have a little question. i have a compiled .exe script and i have created a filecreateshortcut to install the compiled script. script works and it creates the shortcut link in the desktop. however, everytime i executed the shortcut link of the program it successively executes the program and put itself in the tray. what i want to happen is, if the program is running it will just prompt for a simple messagebox that program is currently running. i modified the compiled script and put ProcessExists command but could not detect if program is running.

Any idea how this will work? Thank you.

Filecreate shortcut script:

$file_source = "\\server1\exe$\test.exe"
$file = FileExists(@SystemDir & "\test.exe")
$icon = "\\server1\exe$\server.ico"

If Not $file Then       
    FileCopy($file_source, @SystemDir, 1)
    FileCreateShortcut(@SystemDir & "\test.exe", @DesktopDir & "\test.lnk", @SystemDir, "", "Link", $icon, "{F1}", "0")
Else
    Exit
EndIf

[Zinthose]

There is a UDF available that dose just that

#include <Misc.au3>
if _Singleton("test",1) = 0 Then
    Msgbox(0,"Warning","An occurence of test is already running")
    Exit
EndIf
Msgbox(0,"OK","the first occurence of test is running")

[JohnRichard]

There is a UDF available that dose just that

#include <Misc.au3>
if _Singleton("test",1) = 0 Then
    Msgbox(0,"Warning","An occurence of test is already running")
    Exit
EndIf
Msgbox(0,"OK","the first occurence of test is running")

thanks...shall i include this script into my compiled script?

[JohnRichard]

thank you very much Zinthose. i put it on my compiled script and it does work perfectly...

[grasbmp]

thank you very much Zinthose. i put it on my compiled script and it does work perfectly...

Also just added this snippet to my program - thanks a lot!!

[Valuater]

I use this as there is no "overhead" for all the functions in the include file

If UBound(ProcessList(@ScriptName)) > 2 Then
    MsgBox(4096, "Error", "XSkin-Pro Was already running.     ", 5)
    Exit
EndIf

8)

[Melba23]

Valuater,

I am sure you know already ;-) but for others reading, if you compile using Obfuscator and use the /StripOnly parameter, only the functions you use in each include file are added to the compiled .exe. So in this case, you can use _Singleton and not have "overhead" of the other functions int the Misc.au3 include.

You do need the full SciTE4AutoIt3 package though - but it offers so many advantages over the 'SciTE lite' in the normal install you really should have it anyway :-)

M23

[GodlessSinner]

The simple way to detect if any .exe is running - is to open it for writing and check @ERROR

Edited June 2, 2009 by Vitas

[martin]

You could also copy the _Singleton function into your script and edit it to fit your needs. It can be trimmed down to only seven lines if Const $iFlag = 0, and nine lines if Const $iFlag = 1.

It's not as short as Valuater's potentially one line alternative, but his method doesn't offer a unique ID for each script and can be easily bypassed.

_Singleton is confusing IMO, so I prefer to use this

If _MutexExists("MydeswswScriptName") Then
; We know the script is already running. Let the user know?
    MsgBox(0, "Script Name", "This script is already running.!")
    Exit
EndIf

Func _MutexExists($sOccurenceName)
    Local $ERROR_ALREADY_EXISTS = 183, $handle, $lastError
    
    $sOccurenceName = StringReplace($sOccurenceName, "\", ""); to avoid error as Valik did
    $handle = DllCall("kernel32.dll", "int", "CreateMutex", "int", 0, "long", 1, "str", $sOccurenceName)

    $lastError = DllCall("kernel32.dll", "int", "GetLastError")
    Return $lastError[0] = $ERROR_ALREADY_EXISTS
    
EndFunc ;==>_MutexExists