[Solved] Count array without empty entries

[Hest]

I'm having a little trouble finding the right function to count my array.

I have an array that can have a random number of entries, but when I use Ubound to count the array, it also counts the entries that are empty. I can get up to 365 entries total in the array

Global $value[10] = [100, 132, 138, 117, 122, 108, 130]

Can I somehow make an array where I dont have a preset number ($value[] = [100, 132, 138, 117, 122, 108, 130]) or can I somehow find a result of 7 entries with my array example?

I don't want to loop through the array and check for empty entries if there are other ways to do it.

Edited May 6, 2009 by Hest

[99ojo]

I'm having a little trouble finding the right function to count my array.

I have an array that can have a random number of entries, but when I use Ubound to count the array, it also counts the entries that are empty. I can get up to 365 entries total in the array

Global $value[10] = [100, 132, 138, 117, 122, 108, 130]

Can I somehow make an array where I dont have a preset number ($value[] = [100, 132, 138, 117, 122, 108, 130]) or can I somehow find a result of 7 entries with my array example?

I don't want to loop through the array and check for empty entries if there are other ways to do it.

Hi,

#include <array.au3>
Global $value[10] = [100, 132, 138, 117, 122, 108, 130]
$aresult = _ArrayFindAll ($value, "")
MsgBox (0,"", UBound ($value) - UBound ($aresult))

;-))

Stefan

[MrCreatoR]

I don't want to loop through the array and check for empty entries if there are other ways to do it.

No there isn't, you must loop through the array to check the empty entries.

[Juvigy]

Sort the array , find the min and max value index. The empty entries will be right after the min or max value , have to test to find out.

[MrCreatoR]

But it's better to generate the array in the way that allows you to use only non empty entries, for example:

#include <Array.au3>

Global $avArray[100]

For $i = 1 To 15
    $avArray[0] += 1
    
    $avArray[$i] = "Some data #" & $i
Next

_ArrayDisplay($avArray)

;Here we use the [0] to indicate where non empty entries ending
For $i = 1 To $avArray[0]
    ConsoleWrite($avArray[$i] & @CRLF)
    
    If $avArray[$i] = "" Then MsgBox(64, 'Title', 'Empty entry: ' & $i) ;This will never be shown, since we check only filed entries
Next

[Hest]

Thx to all of you.

I'll give Stefans idear a try and see how it works out.

[Zinthose]

Here are two examples but the" for loop" version is fastest.

#include 'array.au3'

Global $value[10] = [100, 132, 138, 117, 122, 108, 130]
Global $result = 0
Global $timer = 0, $dif = 0

$timer = TimerInit()
$result = _ArrayCount($value)
$dif = TimerDiff($timer)

ConsoleWrite("_ArrayCount = " & $dif & @CRLF)
ConsoleWrite("     result = " & $result & @CRLF)

$timer = TimerInit()
$result = _ArrayCountv2($value)
$dif = TimerDiff($timer)

ConsoleWrite("_ArrayCountv2 = " & $dif & @CRLF)
ConsoleWrite("       result = " & $result & @CRLF)

Func _ArrayCount(ByRef $Array)
    Local $Undefined = _ArrayFindAll($Array, "")
    Return UBound($Array) - UBound($undefined)
EndFunc

Func _ArrayCountv2(ByRef $Array)
    Local $i, $count = 0
    
    For $i = 0 To UBound($Array) - 1
        If $Array[$i] <> "" Then $count += 1
    Next
    
    Return $count
EndFunc

Results

• _ArrayCount = 0.613206427073832 ms
• _ArrayCountv2 = 0.0466539741782824 ms

[GEOSoft]

How did you create the array? If it was with _FileReadToArray() then there is a faster method you could use with RegExp.

[Hest]

How did you create the array? If it was with _FileReadToArray() then there is a faster method you could use with RegExp.

I'll have a look at that also. I'm going to read everything from a file and into an array.

Here are two examples but the" for loop" version is fastest.

Thx to you too. I tried the script Stefan wrote and thats alot slower than the for script

I have something to work with now.

[GEOSoft]

$aRegExp = StringRegExp(FileRead("C:\some\path\myfile.txt", "(?i)\s*(\S\V*)\v?", 3)
$iLines = Ubound($aRegExp)

$aRegExp will not contain any blank Elements so $iLines will be the number of non-empty lines

Note This can also be used to read the file to an array. It also strips leading space from each line.

[Hest]

$aRegExp = StringRegExp(FileRead("C:\some\path\myfile.txt", "(?i)\s*(\S\V*)\v?", 3)
$iLines = Ubound($aRegExp)

$aRegExp will not contain any blank Elements so $iLines will be the number of non-empty lines

Note This can also be used to read the file to an array. It also strips leading space from each line.

Thx, this I can use. Will make it alot faster. How can I store everything in an array?

[GEOSoft]

Thx, this I can use. Will make it alot faster. How can I store everything in an array?

$aRegExp is an array. It just doesn't have leading spaces or empty elements. Edited May 5, 2009 by GEOSoft