how to stop ...

[lesar]

how to stop countdown by using STOP or X button ?

#include <GUIConstantsEx.au3>

GUICreate(" klikor", 210,80, @DesktopWidth/2, @DesktopHeight/2)
$file_1 = GUICtrlCreateInput ( "", 10,  5, 30, 20)
$file_2 = GUICtrlCreateInput ( "", 60, 5, 30, 20)
$file_3 = GUICtrlCreateInput ( "", 110, 5, 30, 20)
$Button_1 = GUICtrlCreateButton ("OK",60,50,40, 20)
$Button_2 = GUICtrlCreateButton ("STOP",110,50,40, 20)
$wynik=GUICtrlCreateLabel("",10,50,40,20)
GUISetState(@SW_SHOW)
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    if $msg = $Button_1 Then
        $file=GUICtrlRead($file_1)+GUICtrlRead($file_2)*60+GUICtrlRead($file_3)*3600
        for $i=$file to 0 step -1
            GUICtrlSetData($wynik,$i)
            $msg=guigetmsg()
            sleep(1000)
            if $msg=$GUI_EVENT_CLOSE or $msg=$Button_2 Then EXITloop
        next    
    endif
Wend

[WideBoyDixon]

expandcollapse popup

#include <GUIConstantsEx.au3>

GUICreate(" klikor", 210, 80, @DesktopWidth / 2, @DesktopHeight / 2)
$file_1 = GUICtrlCreateInput("", 10, 5, 30, 20)
$file_2 = GUICtrlCreateInput("", 60, 5, 30, 20)
$file_3 = GUICtrlCreateInput("", 110, 5, 30, 20)
$Button_1 = GUICtrlCreateButton("OK", 60, 50, 40, 20)
$Button_2 = GUICtrlCreateButton("STOP", 110, 50, 40, 20)
$wynik = GUICtrlCreateLabel("", 10, 50, 40, 20)
GUISetState(@SW_SHOW)
$fRunning = False
$nCount = 0
$iTimer = 0
$sLast = ""
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    If $msg = $Button_1 Then
        If Not $fRunning Then
            $nCount = GUICtrlRead($file_1) + GUICtrlRead($file_2) * 60 + GUICtrlRead($file_3) * 3600
            $fRunning = True
            $iTimer = TimerInit()
        EndIf
    EndIf
    If $msg = $Button_2 Then
        If $fRunning Then
            $fRunning = False
            GUICtrlSetData($wynik, "")
        EndIf
    EndIf
    If $fRunning Then
        $nTDiff = TimerDiff($iTimer)
        $sThis = String($nCount - Int($nTDiff / 1000))
        If $sThis <> $sLast Then
            $sLast = $sThis
            GUICtrlSetData($wynik, $sThis)
        EndIf
        If $sThis = "0" Then
            $fRunning = False
            Msgbox(64, "Timer", "Finished")
            GUICtrlSetData($wynik, "")
        EndIf
    EndIf
    Sleep(10)
WEnd

WBD

[bogQ]

quik edit

#include <GUIConstantsEx.au3>
Global $file
GUICreate(" klikor", 210,80, @DesktopWidth/2, @DesktopHeight/2)
$file_1 = GUICtrlCreateInput ( "", 10,  5, 30, 20)
$file_2 = GUICtrlCreateInput ( "", 60, 5, 30, 20)
$file_3 = GUICtrlCreateInput ( "", 110, 5, 30, 20)
$Button_1 = GUICtrlCreateButton ("OK",60,50,40, 20)
$Button_2 = GUICtrlCreateButton ("STOP",110,50,40, 20)
$wynik=GUICtrlCreateLabel("",10,50,40,20)
GUISetState(@SW_SHOW)
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then Exit
    if $msg = $Button_1 Then
        If $file = "" Then
            $file=GUICtrlRead($file_1)+GUICtrlRead($file_2)*60+GUICtrlRead($file_3)*3600
        EndIf
        AdlibEnable ( "function" ,1000 )
    endif
    if $msg = $Button_2 Then
        AdlibDisable()
    endif
Wend
Func function()
    If $file <> 0 Then $file = $file -1
    GUICtrlSetData($wynik,$file)
    $msg=guigetmsg()
EndFunc

or you can try timedif

[lesar]

big thx

[GEOSoft]

another method would be to set a hotkey to exit the loop.

#include <GUIConstantsEx.au3>
Global $file
GUICreate(" klikor", 210,80, @DesktopWidth/2, @DesktopHeight/2)
$file_1 = GUICtrlCreateInput ( "", 10,  5, 30, 20)
$file_2 = GUICtrlCreateInput ( "", 60, 5, 30, 20)
$file_3 = GUICtrlCreateInput ( "", 110, 5, 30, 20)
$Button_1 = GUICtrlCreateButton ("OK",60,50,40, 20)
$Button_2 = GUICtrlCreateButton ("STOP",110,50,40, 20)
$wynik=GUICtrlCreateLabel("",10,50,40,20)
GUISetState(@SW_SHOW)
While 1
    $msg = GUIGetMsg()
    Switch $Msg
       Case $GUI_EVENT_CLOSE, $Button_2
           ExitLoop
       Case $Button_1 
        If $file = "" Then
            $file=GUICtrlRead($file_1)+GUICtrlRead($file_2)*60+GUICtrlRead($file_3)*3600
            HotKeySet("{End}", "Dummy")
            for $i=$file to 0 step -1
                GUICtrlSetData($wynik,$i)
                sleep(1000)
                If @HotKeyPressed() = "{End}" Then
                    HotKeySet("{End}")
                    ExitLoop
                EndIf
            next  
        EndIf
       Case Else
    EndSwitch
Wend
Func Dummy()
   ;
EndFunc

Edited May 13, 2009 by GEOSoft