CheckBox questions

[TheBG]

Hi. I'm pretty new to Autoit, but I have made several scripts for installing apps.

now i'm trying to make a Gui to pick and select applications to install.

In short, I want to make a gui that has the application list, the user picks the apps they need, and press install.

How do I check if a checkbox is checked> and then make it run another autoit script?

below is my base setup

Opt("WinWaitDelay",100)
Opt("WinTitleMatchMode",4)
Opt("WinDetectHiddenText",1)
Opt("WinTitleMatchMode", 4)


#include <GUIConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 270, 197, 192, 124)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 32, 24, 113, 25)
$Button1 = GUICtrlCreateButton("Button1", 24, 160, 105, 33, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            If $Checkbox1 =  True Then
                Run("\\age-cims\software$\EngStd.exe")
                EndIf
    EndSwitch
WEnd

[Melba23]

TheBG,

You need to use GUICtrlRead. But it is not that simple for Checkboxes and Radiobuttons, where the state of the control is returned. You need to BitAnd the return value with the result you want - the following is true if the Checkbox is checked:

If BitAnd(GUICtrlRead($hCheckbox), $GUI_CHECKED) Then

I hope this is clear - the Help file for GUICtrlRead explains it all as well if you need a second bite. ;-)

M23

[AdmiralAlkex]

Ahh checkboxes can be tricky sometimes. Way down in the "remarks section" of the function GUICtrlRead it is explained how to handle them =

For Checkbox, Radio control several states can be returned as $GUI_FOCUS and $GUI_CHECKED,. So use i.e. BitAnd(GUICtrlRead($Item),$GUI_CHECKED) to test if the control is checked.

That means that the line "If $Checkbox1 = True Then" should be changed to something like "If BitAnd(GUICtrlRead($Checkbox1), $GUI_CHECKED) = True Then"

Edit: Melba23 writes to fast

Edited May 13, 2009 by AdmiralAlkex

[KenNichols]

Try this.

CODE

#include <GUIConstants.au3>

#Region ### START Koda GUI section ###

$Form1 = GUICreate("Run/Install Applications", 270, 197, 192, 124)

$Checkbox1 = GUICtrlCreateCheckbox("Calculator", 32, 24, 113, 25)

$Button1 = GUICtrlCreateButton("Run/Install", 24, 160, 105, 33, 0)

GUISetState(@SW_SHOW)

#EndRegion ### END Koda GUI section ###

While 1

$nMsg = GUIGetMsg()

Switch $nMsg

Case $GUI_EVENT_CLOSE

Exit

Case $Button1

$Checkbox1Checked = GUICtrlRead($Checkbox1)

If $Checkbox1Checked = 1 Then

Run("calc.exe")

EndIf

EndSwitch

WEnd

[GEOSoft]

Better yet

Switch $nMsg
    Case $GUI_EVENT_CLOSE
        Exit

    Case $Button1
        If BitAND(GUICtrlRead($Checkbox1), 1) Then Run("calc.exe")
EndSwitch

[TheBG]

Awesome!!! thanks everyone for the info.

[TheBG]

Ok, One more question. I can't seem to figure this one out.

How can I get the checkbox to reset itself to unchecked after I hit the main $Button1?

I've been trying GUICtrlSetState, but have no luck.

[AdmiralAlkex]

I made an example based on the code previously posted here:

Opt("WinWaitDelay",100)
Opt("WinTitleMatchMode",4)
Opt("WinDetectHiddenText",1)
Opt("WinTitleMatchMode", 4)

#include <GUIConstantsEx.au3>;GUIConstants was replaced a long time ago

#Region ### START Koda GUI section ###
$Form1 = GUICreate("Run/Install Applications", 270, 197, 192, 124)
$Checkbox1 = GUICtrlCreateCheckbox("Calculator", 32, 24, 113, 25)
$Button1 = GUICtrlCreateButton("Run/Install", 24, 160, 105, 33, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            If BitAnd(GUICtrlRead($Checkbox1),$GUI_CHECKED) Then
                Run("calc.exe")
                GUICtrlSetState($Checkbox1, $GUI_UNCHECKED)
            EndIf
    EndSwitch
WEnd

[TheBG]

Many thanks for the help!

I see now that I was not using the setstate appropriately.