Wrong order within listbox

[blum]

I want to use a listbox to display log entries. The newest entry one should be the topmost entry within the listbox, so the user can overview the last events without scrolling.

The following function displays the message strings in the wrong order within the listbox - but i don't know why. The routine puts $vMessage in front of $vLogString, so the latest message is saved before the older ones. I misaccepted that the first substring is displayed in the first line of the listbox - wrong, it will be displayed in the last line; in the order of their occurrence within the code execution. But this is not the order of this routine - can anybody help me with the logic? Have I missed a necessary command?

Version is AI 3.3.0.0 stable.

Global $vLogString=""

AddLogEntry("line1")
AddLogEntry("line2")

Func AddLogEntry($vMessage)
  $vMessage=@Hour & ":" & @MIN & ":" & @SEC & " " & $vMessage
  if $vLogString<>"" Then $vMessage = $vMessage & "|"
  $vLogString = $vMessage & $vLogString

  Dim $vData=""
  $vData=StringSplit($vLogString,"|")

  GUICtrlSetData($ListLog, "")

  For $i=1 to UBound($vData)-1
;msgbox (0,"",UBound($vData)-1 & "/" & $i & ": " & $vData[$i])
   GUICtrlSetData($ListLog, $vData[$i])
  Next

EndFunc

Output in listbox is:

10:15:05: line 1

10:15:10: line 2

...but assumed is

10:15:10:line 2

10:15:05:line 1

Edited May 16, 2009 by blum

[GEOSoft]

#include<array.au3>
Global $vLogString=""

AddLogEntry("line1")
AddLogEntry("line2")

Func AddLogEntry($vMessage)
  $vMessage=@Hour & ":" & @MIN & ":" & @SEC & " " & $vMessage
  if $vLogString<>"" Then $vMessage = $vMessage & "|"
  $vLogString = $vMessage & $vLogString

  Dim $vData=""
  $vData=StringSplit($vLogString,"|")
  _ArraySort($vData, 1, 1, Ubound($vData))
  GUICtrlSetData($ListLog, "")

  For $i=1 to UBound($vData)-1
;msgbox (0,"",UBound($vData)-1 & "/" & $i & ": " & $vData[$i])
   GUICtrlSetData($ListLog, $vData[$i])
  Next

EndFunc

Edited May 16, 2009 by GEOSoft

[Melba23]

blum,

When you create the listbox, I presume you did not specify any styles - in that case you get the default: $LBS_SORT, $WS_BORDER, $WS_VSCROLL. As a result, your listbox is automatically sorting the input for you.

Add the following style to your listbox: BitOr($WS_BORDER, $WS_VSCROLL) and then your function can read:

Func AddLogEntry($vMessage)
    
  $vMessage = "|" & @Hour & ":" & @MIN & ":" & @SEC & " " & $vMessage
  $vLogString = $vMessage & $vLogString
  
  GUICtrlSetData($ListLog, $vLogString)
  
EndFunc

Adding the leading "|" makes the data replace the existing data - so no need to empty the listbox first. ;-)

Works for me!

M23

[GEOSoft]

What Melba23 said plus what I said.

Also I would change the line

$vMessage = "|" & @Hour & ":" & @MIN & ":" & @SEC & " " & $vMessage

To

$vMessage = StringFormat("%s:%s:%s %s", @Hour, @Min, @Sec, $vMessage)

You may find that the change comes in handy later on

[blum]

ahhh, i see. at first i missed the parameter to the listbox. it's right, the auto-sort was applied. the other tips are great, too.

at first i tried to generate the listbox content via the delimited string but the default sort-flag mixed up my order. the array calls are just to demonstrate the step by step addition. now the routine is such short as melba suggested.

thanx!