MsgBox _IELinkGetCollection() in Random Order..?

[cypher175]

How could I MsgBox all URL's of the links on a webpage that _IELinkGetCollection($IE) returns but in a Random Order though..??

The code below is what I got so far, but it seems to repeat some links more than once though..??

I just want it to MsgBox each link's URL only once but in random order though for every link on the webpage..

Whats wrong/missing in my code..??

$GetLinks = _IELinkGetCollection($IE)
$NumLink = @extended
For $INDEX = 1 To $NumLink
    $Random = Random(0,$NumLink,1)
        $Link = _IELinkGetCollection($IE, $Random)
        MsgBox(0,"",$Link.href)
Next

[DaleHohm]

What possible reason do you have for doing this? Sounds like what you want is shuffled, not random.

Dale

[cypher175]

How would i do it shuffled then..??

[DaleHohm]

You were wise to remove your last reply. It made the difference between getting the example below and me telling you good luck, go take a class.

Your lack of understanding of the two concepts is the reason your code fails.

Random, the way you used it in your example is like tossing 20 darts at a dart board with your eyes closed and expecting to get each number only once. Shuffle is analygous to pulling 20 numbered balls out of a bag - you are guaranteed to get each number only once.

What you need to do is to apply a random order to a fixed set. You can use the Random function in this exercise, but you need a level of indirection. The following example does this by applying a random ordering to an array with the same number of elements as you want to shuffle, then using that shuffled order to display your data:

#include <IE.au3>
#include <Array.au3>

$oIE = _IECreate("www.autoitscript.com")

$oLinks = _IELinkGetCollection($oIE)
$NumLink = @extended

Dim $aSet[$Numlink][2]

For $i = 0 to $Numlink - 1
    $aSet[$i][0] = $i
    $aSet[$i][1] = Random(0,1)
Next

_ArrayDisplay($aSet)
_ArraySort($aSet, 0, 0, 0, 1)
_ArrayDisplay($aSet)

For $i = 0 to $Numlink - 1
    $oLink = $oLinks.item($aSet[$i][0])
    MsgBox(0,$oLink.innerText,$oLink.href)
Next

Dale