Window Size

[dantay9]

I would like to know how to make all windows have a limited size so I can add a bar on the side of the window. I want it to look like a widget bar, but that isn't what it is for. I know this can be done, probably with multiple dll calls, I just don't know how. I want extra space on the edge of the desktop even when windows are maximized.

Edited May 26, 2009 by dantay9

[Authenticity]

http://msdn.microsoft.com/en-us/library/ms...28VS.85%29.aspx

You're looking for SPI_SETWORKAREA.

[dantay9]

I tried that out, but I don't think I am doing it right. Here's what I got:

Global Const $SPIF_SENDCHANGE = 0x0002
$Structure = DllStructCreate("int var1; int var2; int var3; long var4")
DllStructSetData($Structure, "var1", 0)
DllStructSetData($Structure, "var2", 0)
DllStructSetData($Structure, "var3", 500)
DllStructSetData($Structure, "var4", 500)
DllCall("user32.dll", "int", "SystemParametersInfo", "uint", "SPI_SETWORKAREA", "uint", 0, "ptr", $Structure, "uint", $SPIF_SENDCHANGE)

[Authenticity]

It's a constant not a string.

#define SPI_SETWORKAREA          0x002F

[dantay9]

It doesn't work. When I maximize windows, they still cover the whole screen. Am I still doing something wrong?

Global Const $SPIF_SENDCHANGE = 0x0002
 $Structure = DllStructCreate("int var1; int var2; int var3; long var4")
 DllStructSetData($Structure, "var1", 0)
 DllStructSetData($Structure, "var2", 0)
 DllStructSetData($Structure, "var3", 500)
 DllStructSetData($Structure, "var4", 500)
 MsgBox(0, '', DllCall("user32.dll", "int", "SystemParametersInfo", "uint", 0x002F, "uint", 0, "ptr", $Structure, "uint", $SPIF_SENDCHANGE))

Edited May 23, 2009 by dantay9

[Yashied]

It doesn't work. When I maximize windows, they still cover the whole screen. Am I still doing something wrong?

Global Const $SPIF_SENDCHANGE = 0x0002
 $Structure = DllStructCreate("int var1; int var2; int var3; long var4")
 DllStructSetData($Structure, "var1", 0)
 DllStructSetData($Structure, "var2", 0)
 DllStructSetData($Structure, "var3", 500)
 DllStructSetData($Structure, "var4", 500)
 MsgBox(0, '', DllCall("user32.dll", "int", "SystemParametersInfo", "uint", 0x002F, "uint", 0, "ptr", $Structure, "uint", $SPIF_SENDCHANGE))

DllCall("user32.dll", "int", "SystemParametersInfo", "uint", 0x002F, "uint", 0, "ptr", DllStructGetPtr($Structure), "uint", $SPIF_SENDCHANGE)

[Authenticity]

DllCall("user32.dll", "int", "SystemParametersInfo", "uint", 0x002F, "uint", 0, "ptr", DllStructGetPtr($Structure), "uint", $SPIF_SENDCHANGE)

...and MsgBox will return always 0 because that it what it shows when you pass in an array type variable.

[dantay9]

Thank you for your help and patience. The limits work when the window is maximized, but when the window isn't maximized, it can still go into the area for the "widget bar". How can I fix that?

Global Const $SPIF_SENDCHANGE = 0x0002
$Structure = DllStructCreate("int var1; int var2; int var3; int var4")
DllStructSetData($Structure, "var1", 0)
DllStructSetData($Structure, "var2", 0)
DllStructSetData($Structure, "var3", @DesktopWidth / 2)
DllStructSetData($Structure, "var4", @DesktopHeight)
DllCall("user32.dll", "int", "SystemParametersInfo", "uint", 0x002F, "uint", 0, "ptr", DllStructGetPtr($Structure), "uint", $SPIF_SENDCHANGE)

Edited May 23, 2009 by dantay9

[Authenticity]

Heh, that is the annoying thing. If your window has always on top such as the taskbar window then if another window has also $WM_EX_TOPMOST extended style it'll go over top of yours, and the top of the taskbar window for that matter. In my opinion you can make your window top most but if another window is willing to go top over your window you should allow it and not play annoying WinMove tricks :}.

[dantay9]

I found exactly what I want, but I don't understand all the dll calls and the functions. It makes a widget bar and allows widgets to be added. All I want is the widget bar. I need help understanding the code. If someone could cut out the code that makes the widget bar and explain to me what each of the dll calls and functions are doing, that would be great! Here's the link:

http://www.autoitscript.com/forum/index.ph...rank%27s+gadget

[Yashied]

I found exactly what I want, but I don't understand all the dll calls and the functions. It makes a widget bar and allows widgets to be added. All I want is the widget bar. I need help understanding the code. If someone could cut out the code that makes the widget bar and explain to me what each of the dll calls and functions are doing, that would be great! Here's the link:

http://www.autoitscript.com/forum/index.ph...rank%27s+gadget

Why do not you ask the author?

[dantay9]

I just figured I would post it on the forum so I could get everyone's opinions and ideas. Do you know how the widget bar is formed?

[picea892]

Hi I was wondering if someone could provide a demonstration or tell me how to use the SPI_GETWORKAREA to get the work space dimensions. Sorry if this is considered hijacking a thread but the topic is same, just in reverse.

[Authenticity]

#include <WinAPI.au3>

Global Const $SPI_GETWORKAREA = 0x0030

Global $tRECT, $pRECT
Global $aRet

$tRECT = DllStructCreate($tagRECT)
$pRECT = DllStructGetPtr($tRECT)

$aRet = DllCall('user32.dll', 'int', 'SystemParametersInfo', 'uint', $SPI_GETWORKAREA, 'uint', 0, _
            'ptr', $pRECT, 'uint', 0)

If Not @error And $aRet[0] Then
    ConsoleWrite(StringFormat("Width: %d\tHeight: %d\n", DllStructGetData($tRECT, 'Right'), _
            DllStructGetData($tRECT, 'Bottom')))
Else
    ConsoleWrite(_WinAPI_GetLastErrorMessage())
EndIf