Recognize softwares which installed on PC

[sarita]

Hi,

Does anyone knows how can i recognize which softwares are installed on specific PC?

I would like to preset it to the user in GUI.

Thanks,

sarita

[system24]

http://www.autoitscript.com/forum/index.php?showtopic=81467

[Danny35d]

$SoftwareList = _SoftwareInventory()
_ArrayDisplay($SoftwareList)

$SoftwareList = _SoftwareInventory('AutoIt v3.3.0.0')
If Not @error Then _ArrayDisplay($SoftwareList)

Func _SoftwareInventory($sFindSoftwareName = '', $sComputer = '')
    Local $iCount = 0

    If $sComputer <> '' Then $sComputer = '\\' & StringReplace($sComputer, '\', '') & '\'
    Local Const $sRegUnistallKey = $sComputer & 'HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall'

    While 1
        $iCount += 1
        $sKey = RegEnumKey($sRegUnistallKey, $iCount)
        If @error <> 0 Then ExitLoop
        $sDisplayName = StringReplace(RegRead($sRegUnistallKey & '\' & $sKey, 'Displayname'), ' (remove only)', '')
        $iDisplayVersion = RegRead($sRegUnistallKey & '\' & $sKey, 'DisplayVersion')

        If $sDisplayName <> '' Then
            If $sFindSoftwareName <> '' And StringInStr($sDisplayName, $sFindSoftwareName) = 0 Then ContinueLoop
            If Not IsDeclared('aSoftwareList') Then Dim $aSoftwareList[1][2]
            ReDim $aSoftwareList[UBound($aSoftwareList) + 1][2]
            $aSoftwareList[UBound($aSoftwareList) - 1][0] = $sDisplayName 
            $aSoftwareList[UBound($aSoftwareList) - 1][1] = $iDisplayVersion
        EndIf      
    WEnd

    If Not IsDeclared('aSoftwareList') Or Not IsArray($aSoftwareList) Then
        Return (SetError(1, 0, ''))
    Else
        $aSoftwareList[0][0] = UBound($aSoftwareList) - 1
        Return (SetError(0, 0, $aSoftwareList))
    EndIf
EndFunc   ;==>_SoftwareInventory