Simple question, but I feel that it impossible to do:(

[GodlessSinner]

I need to break loop by pressing button "Cancel".

(I dont want to use context menu in tray or use HotKeys)

(I know that Func Cancel() will not be called before ExitLoop)

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $started = 0
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 392, 90, 397, 535)
$Time = GUICtrlCreateInput("100", 16, 16, 145, 21, BitOR($ES_CENTER,$ES_AUTOHSCROLL,$ES_NUMBER))
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$Start = GUICtrlCreateButton("Start", 184, 16, 129, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Start
        If $started = 0 Then
            $started =1
            GUICtrlSetData($Start,"Cancel")
            start() 
        ElseIf $started = 1 Then
            $started = 0
            GUICtrlSetData($Start,"Start")
            cancel()
        EndIf   
    EndSwitch
WEnd
Func Start()
        For $i = GUICtrlRead($Time) To 0 Step -1
            if $started =0  Then ExitLoop
            Sleep(1000)
            GUICtrlSetData($Time, $i)
        Next
    ;Shutdown,1
EndFunc
Func Cancel()
    $started =0 
EndFunc

[MrCreatoR]

You can use OnEvent mode and Adlib*:

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;

Global $Started = 0

Opt("GUIOnEventMode", 1)

$Form1 = GUICreate("Form1", 392, 90, 397, 535)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit_Proc")

$Time = GUICtrlCreateInput("100", 16, 16, 145, 21, BitOR($ES_CENTER, $ES_AUTOHSCROLL, $ES_NUMBER))
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")

$Start = GUICtrlCreateButton("Start", 184, 16, 129, 25, 0)
GUICtrlSetOnEvent($Start, "Start_Button_Event")

GUISetState(@SW_SHOW)

While 1
    Sleep(1000)
WEnd

Func Start_Button_Event()
    $Started = Not $Started
    
    If $Started Then
        GUICtrlSetData($Start, "Cancel")
        AdlibEnable("Start_Proc", 1)
    Else
        GUICtrlSetData($Start, "Start")
    EndIf
EndFunc

Func Start_Proc()
    AdlibDisable()
    
    For $i = GUICtrlRead($Time) To 0 Step -1
        If Not $Started Then ExitLoop
        
        Sleep(1000)
        GUICtrlSetData($Time, $i)
    Next
    
    ;Shutdown,1
EndFunc

Func _Quit_Proc()
    Exit
EndFunc

[trancexx]

Or maybe something like this (I deleted things):

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $started = 0
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 392, 90, 397, 535)
$Time = GUICtrlCreateInput("100", 16, 16, 145, 21, BitOR($ES_CENTER, $ES_AUTOHSCROLL, $ES_NUMBER))
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$Start = GUICtrlCreateButton("Start", 184, 16, 129, 25, 0)
GUISetState(@SW_SHOW)

Global $iSec, $iSec1, $i

#EndRegion ### END Koda GUI section ###

While 1

    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Start
            If $started = 0 Then
                $started = 1
                GUICtrlSetData($Start, "Cancel")
                $i = GUICtrlRead($Time)
            ElseIf $started = 1 Then
                $started = 0
                GUICtrlSetData($Start, "Start")
            EndIf
    EndSwitch

    If $started Then
        $iSec = @SEC
        If $iSec - $iSec1 Then
            $iSec1 = $iSec
            $i -= 1
            GUICtrlSetData($Time, $i)
        EndIf
    EndIf

WEnd

[GodlessSinner]

Thanks all!! It works like I wanted:)