Create an input in the taskbar

[jerem488]

Hello,

I want to say if it is possible to create an input control in the taskbar (like Google Desktop or Windows Search).

Thank you in advance

[MrCreatoR]

Something like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

$hTaskbar_Wnd = WinGetHandle("[CLASS:Shell_TrayWnd]")
$hTaskbarCtrl_Wnd = ControlGetHandle("[CLASS:Shell_TrayWnd]", "", "ToolbarWindow321")

$aTaskbar_Pos = WinGetPos($hTaskbarCtrl_Wnd)

$hGUI = GUICreate("", 80, 22, $aTaskbar_Pos[0]-(80+10), 3, $WS_POPUP, $WS_EX_TOPMOST, $hTaskbar_Wnd)
$Input = GUICtrlCreateInput("Search...", 0, 0, 80, 22)
GUICtrlSetColor(-1, 0xC0C0C0)

GUISetState(@SW_SHOW, $hGUI)
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

_WinAPI_SetParent($hGUI, $hTaskbar_Wnd)

$nDummyEnterID = GUICtrlCreateDummy()

Dim $aAccelKeys[1][2] = [["{ENTER}", $nDummyEnterID]]
GUISetAccelerators($aAccelKeys)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $nDummyEnterID
            $sInput_Read = GUICtrlRead($Input)
            
            If $sInput_Read <> "" Then ShellExecute("http://www.google.ru/search?hl=en&q=" & $sInput_Read)
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $nMsg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    Local $hCtrl = $lParam
    
    Switch $nID
        Case $Input
            Switch $nNotifyCode
                Case $EN_CHANGE, $EN_UPDATE
                    
                Case $EN_SETFOCUS
                    If GUICtrlRead($Input) = "Search..." Then GUICtrlSetData($Input, "")
                    
                    GUICtrlSetColor($Input, 0x0)
                Case $EN_KILLFOCUS
                    If GUICtrlRead($Input) = "" Then GUICtrlSetData($Input, "Search...")
                    
                    GUICtrlSetColor($Input, 0xC0C0C0)
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc

P.S

Can be improved (as always), but it's only an example of possibility

[KaFu]

Really nice , thanks for this example!

[jerem488]

Yes very good script ! But the input is above others windows in the toolbar

In fact, it would be better to use a delimiter...

Thank you

[jerem488]

up ?

[jerem488]

I have see the command _GUICtrlToolbar_AddButtonSep(). Can I use this command to add a separator in the taskbar ???

Or the command _GUICtrlToolbar_Create() ???

Because I search a solution to put a separator in the taskbar ! ! ! !! ! !

Thanks

Edited June 18, 2009 by jerem488

[jerem488]

I saw this function ! ! !

Func _ResizeQuickLaunchBar()
    Local $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    Local $hRebar = ControlGetHandle($hTaskBar, "", "ReBarWindow321")
    Local $hToolBar = ControlGetHandle($hRebar, "", "ToolbarWindow322")
    Local $user_icon_width = 24, $user_icon_height = 30
    Local $user_icons_count = _GUICtrlToolbar_ButtonCount($hToolBar)
    Local $user_icons_rows = _GUICtrlToolbar_GetRows($hToolBar)
    Local $user_bar_height = _GUICtrlRebar_GetRowHeight($hRebar,0)
    _GUICtrlRebar_SetBandLength($hRebar, 0, $user_icons_count/($user_bar_height/$user_icon_height)* $user_icon_width + 160)
EndFunc   ;==>_ShowProgramsShowingInTaskBar

But it resize the quick launch bar...

And me, i want to resize the toolbar where programs windows are.

Edited June 18, 2009 by jerem488

[jerem488]

Do you know how it is to add a separator in the toolbar (ReBarWindow321) ??

I am testing with the _GUICtrlToolbar_AddButtonSep() function, but no separator is added

Thank you