How to delete empty line in INI ?

[microbious]

I got this INI clean up thing going that removes INI sections.

Problem is that once section is removed, it leaves empty line behind because each section is separated from another by an empty line.

I could not find anything that would remove an empty line from INI or TXT document anywhere so i ask you.

If you could please post an example

All i could think of is

$emptyline = "?"
        $replaceline = ""
        $replace = _ReplaceStringInFile ($filename,$emptyline,$replaceline)

but that returns with 0 instead of a number of found empty lines.

What does Empty line stand for in here ? $emptyline = "?"

Edited June 18, 2009 by lessstoopid

[MrCreatoR]

Try this:

_IniDeleteSection("File.ini", "Sect")

Func _IniDeleteSection($sIni_File, $sSect_Name)
    Local $aRead_IniFile = StringSplit(StringStripCR(StringStripWS(FileRead($sIni_File), 3)), @LF)
    
    Local $sIniFile_Content = ""
    
    For $i = 1 To $aRead_IniFile[0]
        If $aRead_IniFile[$i] = "[" & $sSect_Name & "]" Then
            For $j = $i+1 To $aRead_IniFile[0]
                If StringRegExp($aRead_IniFile[$j], "\A(\[|;\[)") Then ExitLoop
            Next
            
            $i = $j-1
        Else
            $sIniFile_Content &= $aRead_IniFile[$i] & @CRLF
        EndIf
    Next
    
    Local $hFOpen = FileOpen($sIni_File, 2)
    FileWrite($hFOpen, StringStripWS($sIniFile_Content, 3))
    FileClose($hFOpen)
EndFunc

Or more simple way:

_IniDeleteSection("File.ini", "Sect")

Func _IniDeleteSection($sIni_File, $sSect_Name)
    IniDelete($sIni_File, $sSect_Name)
    Local $sIniFile_Content = StringRegExpReplace(FileRead($sIni_File), "(\r\n){1,}", "\1")
    
    Local $hFOpen = FileOpen($sIni_File, 2)
    FileWrite($hFOpen, StringStripWS($sIniFile_Content, 3))
    FileClose($hFOpen)
EndFunc

[microbious]

ok then how can i create Func in my GUI if there is no Func at all ?

All i have is the Case for button as

While 1

$nMsg = GUIGetMsg()

Switch $nMsg

Case $button

Case $GUI_EVENT_CLOSE

Exit

EndSwitch

WEnd

Sorry i am still learning and your example is difficult to digest at this point and only one thing i can think of is:

Case $button

$Filename = "file.txt"

$Emptyline = ""

lineremove ($filename,$emptyline)

Thanks

Edited June 18, 2009 by lessstoopid

[MrCreatoR]

While 1
    $nMsg = GUIGetMsg()
    
    Switch $nMsg
         Case $button
              _FileDeleteEmptyLines("File.txt")
         Case $GUI_EVENT_CLOSE
              Exit
    EndSwitch
WEnd

Func _FileDeleteEmptyLines($sFile)
    Local $sFileContent = StringRegExpReplace(FileRead($sFile), "(\r\n){1,}", "\1")
    
    Local $hFOpen = FileOpen($sFile, 2)
    FileWrite($hFOpen, StringStripWS($sFileContent, 3))
    FileClose($hFOpen)
EndFunc

[microbious]

HOLLY Cr@p it worked !!!

WOw with your example i learned that if afre Case i type something as

Case example($var)

Then i can use this Func later on as long as i create

Func example($var)

Very helpful

thank allot