Add a frame to the inputbox

[jerem488]

Hello,

I have an inputbox, and Iwould like to add a frame to this inputbox. I searched on the forum, but i haven't find a solution.

I have seen many solutions to create animations in windows but no around windows.

$hGUI = GUICreate("", 140, 22, @DesktopWidth-(140+10), @DesktopHeight-(54+22+10), $WS_POPUP, $WS_EX_TOPMOST, $hTaskbar_Wnd)
$Input = GUICtrlCreateInput("", 0, 0, 140, 22)
GUICtrlSetColor($Input, 0xC0C0C0)

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Thanks

[Skruge]

I have an inputbox, and Iwould like to add a frame to this inputbox. I searched on the forum, but i haven't find a solution.

I have seen many solutions to create animations in windows but no around windows.

What do you mean by "frame"? Something like this?

A picture of what you're trying to accomplish would help.

$hGUI = GUICreate("", 150, 46, @DesktopWidth-(140+10), @DesktopHeight-(54+22+10), $WS_POPUP, $WS_EX_TOPMOST, $hTaskbar_Wnd)
$Group = GUICtrlCreateGroup("Frame?", 2, 0, 146, 42)
$Input = GUICtrlCreateInput("", 5, 15, 140, 22)
GUICtrlSetColor($Input, 0xC0C0C0)

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

[jerem488]

Like this picture.

[Melba23]

jerem488,

Perhaps this might help?

M23

[James]

This wont work because AutoIt waits till the InputBox has finished it's events, but you can probably do it using some other method:

#Include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$GUI = GUICreate("Form1", 633, 447, 193, 125,BitOR($WS_CLIPCHILDREN,$WS_CLIPSIBLINGS,$WS_MAXIMIZEBOX,$WS_MINIMIZEBOX))
$hInput = InputBox("", "")
_WinAPI_SetWindowLong(WinGetHandle($hInput), $GWL_HWNDPARENT, $GUI)
_WinAPI_SetWindowLong(WinGetHandle($hInput), $GWL_STYLE, BitOR($WS_CLIPCHILDREN,$WS_CHILD,$WS_VISIBLE,$WS_MINIMIZEBOX,$WS_SIZEBOX ))
;~ _WinAPI_SetWindowLong(WinGetHandle("AutoIt Help"), $GWL_EXSTYLE,$WS_EX_MDICHILD)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Actually, I don't think that is what you want.

Edited June 25, 2009 by JamesBrooks

[MrCreatoR]

Like this picture.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#Include <WinAPI.au3>
;

$hGUI = GUICreate("", 220, 62, -1, -1, $WS_POPUP, $WS_EX_TOPMOST)
GUISetBkColor(0x004A84)

$Input = GUICtrlCreateInput("INPUTBOX", 20, 20, 180, 22, BitOR($ES_LEFT, $ES_AUTOHSCROLL, $ES_CENTER))

_GUIRoundCorners($hGUI, 2, 2, 25, 25)

GUISetState(@SW_SHOW, $hGUI)
GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUIRoundCorners($hWnd, $iX1, $iY1, $iX2, $iY2)
    Local $aWPos = WinGetPos($hWnd)
    
    Local $aRet = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", _
        "long", $iX1, "long", $iX1, "long", $aWPos[2], "long", $aWPos[3], "long", $iX2, "long", $iY2)
    
    If IsArray($aRet) And $aRet[0] Then _
        Return DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $hWnd, "long", $aRet[0], "int", 1)
EndFunc

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If $hWnd <> $hGUI Or $iMsg <> $WM_NCHITTEST Then Return $GUI_RUNDEFMSG
    
    Local $iRet = _WinAPI_DefWindowProc($hWnd, $iMsg, $iwParam, $ilParam)
    If $iRet = 1 Then Return 2
    
    Return $iRet
EndFunc

[jerem488]

.... How to say ....

you are simply super !

Thank you