Dynamic created Buttons While/Wend Loop

[Emiel Wieldraaijer]

Hi All,

I've created a GUI which has dynamicly created buttons.

In the example posted these dynamicly based buttons are created on the amount of drives in the computer.

Does anyone know how i can add those dynamic created variables in my loop ?

Thanks

Emiel

#include <GUIConstants.au3>
#include <ButtonConstants.au3>

$Drives = DriveGetDrive("ALL")
Dim $DriveButton[($Drives[0] + 1)]

GuiCreate ("Title", 600, 400)
For $i = 1 To $Drives[0]
    $x = $i * 30 + 50
    $DriveButton[$i] = GUICtrlCreateButton($Drives[$i], $x,80, 30, 30)
Next
GUISetState ()

While 1
    $Msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $DriveButton[1]
            Msgbox (0, "test", "First")
        ; Case $DriveButton[$i] ??????
            ; Command to run
    EndSwitch
Wend

[GEOSoft]

Since I don't know what you are trying to run then this is just a starting point but it should be fairly close.

Dim $DriveButton[($Drives[0] + 1)]

GuiCreate ("Title", 600, 400)
For $i = 1 To $Drives[0]
    $x = $i * 30 + 50
    $DriveButton[$i] = GUICtrlCreateButton($Drives[$i], $x,80, 30, 30)
Next
GUISetState ()

While 1
    $Msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        ;Case $DriveButton[1]
        ;    Msgbox (0, "test", "First")
        Case $DriveButton[1] To $DriveButton[$Drives[0]]
            MsgBox(0, "Test", GUICtrlRead($Msg))
            ; Command to run
    EndSwitch
Wend

Edited July 21, 2009 by GEOSoft

[GEOSoft]

Here is another method I prefer with Dynamic creation of controls

Dim $DriveButton[($Drives[0] + 1)]

GuiCreate ("Title", 600, 400)
$Btn_Start = GUICtrlCreateDummy()
For $i = 1 To $Drives[0]
    $x = $i * 30 + 50
    $DriveButton[$i] = GUICtrlCreateButton($Drives[$i], $x,80, 30, 30)
Next
$Btn_End = GUICtrlCreateDummy()
GUISetState ()

While 1
    $Msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        ;Case $DriveButton[1]
        ;    Msgbox (0, "test", "First")
        Case $Btn_Start To $Btn_End
            MsgBox(0, "Test", GUICtrlRead($Msg))
            ; Command to run
    EndSwitch
Wend

[Emiel Wieldraaijer]

Hi George,

Thanks...

It's more simple than i thought it would be

Best regards,

Emiel