WinAPIEx UDF

[guinness]

An API alternative to FileExist >>

Edited January 12, 2012 by guinness

[Yashied]

But why? FileExists() works fine. Anyway, I added a _WinAPI_FileExists() in the latest release, but it has differences.

[guinness]

But why? FileExists() works fine. Anyway, I added a _WinAPI_FileExists() in the latest release, but it has differences.

Yeh I saw that version with the @extended value, I've moved the code to the wrapper thread as an alternative. When I posted I was torn at which thread I should place this in.

[AvvA]

Hello

Thanks a lot for this library, it makes me avoid hours of mind torture to convert MSDN functions to AutoIt able to use these functions ^^'.

I've got a problem with _WinAPI_GetFinalPathNameByHandleEx() (I also tried with _WinAPI_GetFinalPathNameByHandle() ), I'm using Win7 x64 and AutoIt 3.3.8 x86.

It works perfectly with files but doesn't with folders. I'm trying to use this function to retrieve easily the target of a symbolic link or a junction.

By the way, as I'm here, would it be possible for you to add the FindFirstFileName() and FindNextFileName() functions? I already try several times to convert them without success, it seems easy to do but in fact it isn't.. at least for me.

Their purpose is to find all filenames (and their paths) attached to an MFT entry, it is useful to list all hard links attached to a single file.

Cheers!

[Yashied]

By the way, as I'm here, would it be possible for you to add the FindFirstFileName() and FindNextFileName() functions? I already try several times to convert them without success, it seems easy to do but in fact it isn't.. at least for me.

Their purpose is to find all filenames (and their paths) attached to an MFT entry, it is useful to list all hard links attached to a single file.

It was already added in the latest version.

[AvvA]

It wasn't, you added FindFirstFile/FindNextFile() but not FindFirstFileName/FindNextFileName().

But anyway, the important part of my previous message was, excluding the thanks part, the problem with _WinAPI_GetFinalPathNameByHandleEx()

Edited January 13, 2012 by AvvA

[wraithdu]

What is your error? Are you sure you're passing the function a valid handle? You have to use FILE_FLAG_BACKUP_SEMANTICS with CreateFile to open a handle to a directory, for example.

Edited January 13, 2012 by wraithdu

[AvvA]

I'm confused, sorry Yashied and thanks wraithdu.

I looked at a folder like if it was a file, like it is physically, wrong angle...

I succeed to use this flag with _WinAPI_CreateFileEx() (can' figure it out with _WinAPI_CreateFile), and indeed now I've got the target paths of junctions and symbolic links, that's great!

Thanks a lot for answering my newbie question.

[veronesi]

Hi

Just saw this great UDF.

There are a lot of very usefull functions in it!

Thank you very much for sharing this.

Would it be possible to add the _WinAPI_BackupRead, _WinAPI_BackupWrite and _WinAPI_BackupSeek functions?

With this functions it would be possible to save files including the security informations!

And are there any examples to this functions? I'd like to use theese functions, but at the moment, I wasn't able to convert them into AutoIt.

Thank you very much!

Veronesi

Edited February 14, 2012 by veronesi

[Yashied]

Would it be possible to add the _WinAPI_BackupRead, _WinAPI_BackupWrite and _WinAPI_BackupSeek functions?

With this functions it would be possible to save files including the security informations!

And are there any examples to this functions? I'd like to use theese functions, but at the moment, I wasn't able to convert them into AutoIt.

expandcollapse popup

#Include <APIConstants.au3>
#Include <WinAPIEx.au3>

Global Const $ACCESS_SYSTEM_SECURITY = 0x01000000

Global $aAdjust, $aPrivileges[3] = [$SE_BACKUP_NAME, $SE_RESTORE_NAME, $SE_SECURITY_NAME]
Global $hFile, $pBuffer, $pContext, $Bytes = 4096
Global $sFile = @ScriptFullPath

$hToken = _WinAPI_OpenProcessToken(BitOR($TOKEN_ADJUST_PRIVILEGES, $TOKEN_QUERY))
_WinAPI_AdjustTokenPrivileges($hToken, $aPrivileges, $SE_PRIVILEGE_ENABLED, $aAdjust)

$pBuffer = _WinAPI_CreateBuffer($Bytes)

$pContext = 0
$hFile = _WinAPI_CreateFileEx($sFile, $OPEN_EXISTING, BitOR($GENERIC_READ, $ACCESS_SYSTEM_SECURITY))
_WinAPI_BackupRead($hFile, $pBuffer, $Bytes, $Bytes, $pContext, 0, 1)
_WinAPI_BackupRead(0, 0, 0, $Bytes, $pContext, 1)
_WinAPI_CloseHandle($hFile)

$pContext = 0
$hFile = _WinAPI_CreateFileEx(_WinAPI_PathRenameExtension($sFile, '.bak'), $CREATE_ALWAYS, BitOR($GENERIC_WRITE, $WRITE_DAC, $WRITE_OWNER))
_WinAPI_BackupWrite($hFile, $pBuffer, $Bytes, $Bytes, $pContext, 0, 1)
_WinAPI_BackupWrite(0, 0, 0, $Bytes, $pContext, 1)
_WinAPI_CloseHandle($hFile)

_WinAPI_FreeMemory($pBuffer)

_WinAPI_AdjustTokenPrivileges($hToken, $aAdjust, 0, $aAdjust)
_WinAPI_CloseHandle($hToken)

Func _WinAPI_BackupRead($hFile, $pBuffer, $iLenght, ByRef $iBytes, ByRef $pContext, $fAbort = 0, $fSecurity = 0)

    If Not $fAbort Then
        $iBytes = 0
    EndIf

    Local $Ret = DllCall('kernel32.dll', 'int', 'BackupRead', 'ptr', $hFile, 'ptr', $pBuffer, 'dword', $iLenght, 'dword*', 0, 'int', $fAbort, 'int', $fSecurity, 'ptr*', $pContext)

    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    If Not $fAbort Then
        $iBytes = $Ret[4]
    EndIf
    $pContext = $Ret[7]
    Return 1
EndFunc   ;==>_WinAPI_BackupRead

Func _WinAPI_BackupSeek($hFile, $iSeek, ByRef $iBytes, ByRef $pContext)

    $iBytes = 0

    Local $Ret = DllCall('kernel32.dll', 'int', 'BackupSeek', 'ptr', $hFile, 'dword', _WinAPI_LoDWord($iSeek), 'dword', _WinAPI_HiDWord($iSeek), 'dword*', 0, 'dword*', 0, 'ptr*', $pContext)

    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    $iBytes = _WinAPI_MakeQWord($Ret[4], $Ret[5])
    $pContext = $Ret[6]
    Return 1
EndFunc   ;==>_WinAPI_BackupSeek

Func _WinAPI_BackupWrite($hFile, $pBuffer, $iLenght, ByRef $iBytes, ByRef $pContext, $fAbort = 0, $fSecurity = 0)

    If Not $fAbort Then
        $iBytes = 0
    EndIf

    Local $Ret = DllCall('kernel32.dll', 'int', 'BackupWrite', 'ptr', $hFile, 'ptr', $pBuffer, 'dword', $iLenght, 'dword*', 0, 'int', $fAbort, 'int', $fSecurity, 'ptr*', $pContext)

    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    If Not $fAbort Then
        $iBytes = $Ret[4]
    EndIf
    $pContext = $Ret[7]
    Return 1
EndFunc   ;==>_WinAPI_BackupWrite

Edited February 14, 2012 by Yashied

[veronesi]

Thank you very much for this UDF!

I'll try to use it tomorrow, when I'm in the office.

Thanks again!

Best regards Veronesi

[chandoi]

thank you,

Can you give me some cursor example from resource?

[Yashied]

Can you give me some cursor example from resource?

expandcollapse popup

#Region
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Run_After=ResHacker.exe -add "%out%", "%out%", Lens.cur, 12, 100,
#AutoIt3Wrapper_Run_After=ResHacker.exe -add "%out%", "%out%", Move.cur, 12, 101,
;~#AutoIt3Wrapper_Run_After=UtilitiesUpx.exe %out% --best --no-backup --overlay=copy --compress-exports=1 --compress-resources=0 --strip-relocs=1
#EndRegion

#Include <APIConstants.au3>
#Include <GUIConstantsEx.au3>
#Include <WinAPIEx.au3>

Opt('MustDeclareVars', 1)

Global $hForm, $hInstance, $hLens, $hMove, $Label

$hForm = GUICreate("MyProg", 300, 300)
$hInstance = _WinAPI_GetModuleHandle('')
$hLens = _WinAPI_LoadCursor($hInstance, 100)
$hMove = _WinAPI_LoadCursor($hInstance, 101)
$Label = GUICtrlCreateLabel("", 60, 60, 180, 180)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0xFFD0D0)
GUIRegisterMsg($WM_SETCURSOR, "WM_SETCURSOR")
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_SETCURSOR($hWnd, $iMsg, $wParam, $lParam)

    Local $aInfo

    Switch $hWnd
        Case $hForm
            $aInfo = GUIGetCursorInfo($hForm)
            If (Not @error) And ($aInfo[4] = $Label) Then
                If $aInfo[2] Then
                    _WinAPI_SetCursor($hMove)
                Else
                    _WinAPI_SetCursor($hLens)
                EndIf
                Return 1
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SETCURSOR

Cursor.zip

If you want to learn more about the resources in AutoIt, follow this link (Russian).

EDIT:

An example with a mixed resources.

ListBox.zip

Edited February 29, 2012 by Yashied

[chandoi]

thanks Yashied

I was found

[Yashied]

The library has been updated.

v3.7

• Added the following functions.

  _WinAPI_AdjustBitmap

  _WinAPI_CreateColorAdjustment

  _WinAPI_BackupRead

  _WinAPI_BackupReadAbort

  _WinAPI_BackupSeek

  _WinAPI_BackupWrite

  _WinAPI_BackupWriteAbort

  _WinAPI_CompareString

  _WinAPI_CompressBuffer

  _WinAPI_ConfirmCredentials

  _WinAPI_CreateDirectory

  _WinAPI_CreateHardLink

  _WinAPI_CreateProcessWithToken

  _WinAPI_CreateSymbolicLink

  _WinAPI_DecompressBuffer

  _WinAPI_DecryptFile

  _WinAPI_DrawFocusRect

  _WinAPI_DuplicateEncryptionInfoFile

  _WinAPI_DuplicateTokenEx

  _WinAPI_EncryptFile

  _WinAPI_EncryptionDisable

  _WinAPI_EnumDisplayMonitors

  _WinAPI_EnumFiles

  _WinAPI_EnumFileStreams

  _WinAPI_EnumHardLinks

  _WinAPI_EnumSystemGeoID

  _WinAPI_FileEncryptionStatus

  _WinAPI_FindCloseChangeNotification

  _WinAPI_FindFirstChangeNotification

  _WinAPI_FindFirstFileName

  _WinAPI_FindNextChangeNotification

  _WinAPI_FindNextFileName

  _WinAPI_GetColorAdjustment

  _WinAPI_GetFileID

  _WinAPI_GetFilePointerEx

  _WinAPI_GetGeoInfo

  _WinAPI_GetGlyphOutline

  _WinAPI_GetMonitorInfo

  _WinAPI_GetObjectInfoByHandle

  _WinAPI_GetStretchBltMode

  _WinAPI_GetSystemDefaultLangID

  _WinAPI_GetThreadLocale

  _WinAPI_GetThreadUILanguage

  _WinAPI_GetUserDefaultLangID

  _WinAPI_GetUserGeoID

  _WinAPI_GetVolumeInformation

  _WinAPI_GetVolumeInformationByHandle

  _WinAPI_GetWindowRgnBox

  _WinAPI_HashData

  _WinAPI_HashString

  _WinAPI_IsElevated

  _WinAPI_LoadStringEx

  _WinAPI_MonitorFromPoint

  _WinAPI_MonitorFromRect

  _WinAPI_MonitorFromWindow

  _WinAPI_ParseURL

  _WinAPI_ParseUserName

  _WinAPI_ReadDirectoryChanges

  _WinAPI_SetColorAdjustment

  _WinAPI_SetFileShortName

  _WinAPI_SetThreadLocale

  _WinAPI_SetThreadUILanguage

  _WinAPI_SetUserGeoID

  _WinAPI_ShellUserAuthenticationDlg

  _WinAPI_ShellUserAuthenticationDlgEx

  _WinAPI_UrlApplyScheme

  _WinAPI_UrlCanonicalize

  _WinAPI_UrlCombine

  _WinAPI_UrlCompare

  _WinAPI_UrlHash

  _WinAPI_VerQueryValueEx

• Added examples for the functions above.
• Removed the following functions.

  _WinAPI_GetFileSize (use _WinAPI_GetFileSizeEx)

  _WinAPI_LZNTCompress (use _WinAPI_CompressBuffer)

  _WinAPI_LZNTDecompress (use _WinAPI_DecompressBuffer)

  _WinAPI_ResizeBitmap (use _WinAPI_AdjustBitmap)

  _WinAPI_ShutdownDlg (unnecessary)

  _WinAPI_UrlEscape (use _WinAPI_UrlCanonicalize)

  _WinAPI_UrlUnescape (use _WinAPI_UrlCanonicalize)

• Added $tagFILE_ID_DESCRIPTOR structure.
• Added one optional parameter in _WinAPI_RegSaveKey() function, see its description.
• Added one optional parameter in _WinAPI_GetFileVersionInfo() function, see its description.
• The third and fourth parameters in _WinAPI_OpenFileById() function are now optional (similar to _WinAPI_CreateFileEx()).
• The following functions now works with pointers instead of structures, see its description.

  _WinAPI_CompressBitmapBits

  _WinAPI_GetEnhMetaFileBits

  _WinAPI_GetFileVersionInfo

  _WinAPI_SetEnhMetaFileBits

• The _WinAPI_DeleteObjectID(), _WinAPI_RegRestoreKey(), and _WinAPI_RegSaveKey() functions are no longer enables the necessary privileges to themselves.
• The _WinAPI_GetCompression() function now returns (-1) instead of 0 if an error occured.
• The _WinAPI_OpenFileById() function now can work with file identifiers (FileID).
• The _WinAPI_SetStretchBltMode() function now returns the previous stretching mode.
• The _WinAPI_VerQueryRoot() and _WinAPI_VerQueryValue() functions has been rewrited to work with pointers, instead of files, see its description.
• Fixed examples for some functions.
• Updated documentation.

[UEZ]

Thank you very much again for your contribution on this great work!

Br,

UEZ

[guinness]

Thanks Yashied.

This is no biggy but in the example for _WinAPI_GetVolumeInformation it should be length not lenght.

Edited March 5, 2012 by guinness

[Yashied]

Look at the example for the _WinAPI_CreateColorAdjustment() function.

[Yashied]

The library has been updated, version remains unchanged.

Changes

• Added Installer (see first post).
• Updated documentation.

Edited March 6, 2012 by Yashied

[guinness]

Yashied,

The ZIP files both contain the exact same version of WinAPIEx.au3. How I found out was I got a couple of errors (fixed my side) when compiling a script.

I'm using AutoIt V3.3.8.1 as well as the beta.

Edited March 6, 2012 by guinness