how to delete lines from a file

[KMT]

Hello guys!

I'm very noob at programming, but I have to do a task.

What I have to do is deleting every second line (or odd/even lines) from a simple (but big) data file. It has more than 30000 lines, so I won't do it manually.

Please help me, what commands should I use to do this?!

Thanks in advance!

[water]

Something like this (untested) script. The file is read into an array end every second record - starting with record 2 - is written to an output file.

#include <file.au3>
Dim  $aRecords
If Not _FileReadToArray("Input.txt",$aRecords) Then
   MsgBox(4096,"Error", " Error reading file to Array      error:" & @error)
   Exit
EndIf
$hFile = FileOpen("Output.txt",2)
For $x =  2 to $aRecords[0] step 2 
    FileWrite($hFile,$aRecords[$x])
Next
FileClose($hFile)

[KMT]

Something like this (untested) script. The file is read into an array end every second record - starting with record 2 - is written to an output file.

Thanks.

Seems to be ok, but this confused the lines.

So it should look like:

"line1

line3

line5..."

and it looks like:

"line 1 line 3? line 5?"...

[GEOSoft]

Thanks.

Seems to be ok, but this confused the lines.

So it should look like:

"line1

line3

line5..."

and it looks like:

"line 1 line 3? line 5?"...

Change the FileWrite() to FileWriteLine() or better yet.

#include <file.au3>
Dim  $aRecords
If Not _FileReadToArray("Input.txt",$aRecords) Then
   MsgBox(4096,"Error", " Error reading file to Array      error:" & @error)
   Exit
EndIf

$sText = ""
For $x =  2 to $aRecords[0] step 2
    $sText &= $aRecords[$x] & @CRLF
Next

If $sText Then
    $hFile = FileOpen("Output.txt",2)
    FileWrite($hFile,StringStripWS($sText, 2))
    FileClose($hFile)
EndIf

Also, since the keyword Dim is being phased out, you should get in the habit of using either Global or Local to replace Dim. That particularily applies in a case like this where Dim is not Dim(ension)ing anything. It's an empty string.

Edited July 23, 2009 by GEOSoft

[KMT]

This works.

Thank you very much for your help!

[Malkey]

This is another method that appears to works.

I am guessing this is faster. I haven't done any comparative speed testing.

;
Local $sFileIn = "test.txt"
Local $sFileOut = "TestOut.txt"

If FileExists($sFileIn) = 0 Then Exit

Local $filtxt = FileRead($sFileIn)
;Local $sStr = StringRegExpReplace($filtxt, "((.*\v+)|(.*$))((.*\v+)|(.*$))", "\2") ; Back-reference, \2, returns 1st line, 3rd line , 5th, ...
Local $sStr = StringRegExpReplace($filtxt, "((.*\v+)|(.*$))((.*\v+)|(.*$))", "\4") ; Back-reference, \4, returns 2nd line, 4th line , 6th, ...

Local $hFile = FileOpen($sFileOut, 10)
FileWrite($hFile, $sStr)
FileClose($hFile)

;ShellExecute($sFileOut) ; Opens file with the application associated with the file extension.
;