Is it possible to grey out an entire tab?

[Shark007]

I have a simple GUI which contains 10 TABS containing various controls.

I'd like to grey out and entire TAB's interface, or at least its controls if a condition is not met

I've tried variations of...

$SWAP_tab = GUICtrlCreateTabItem("SWAP")

If Not FileExists(@SystemDir & "\aitagent.exe") Then

GUICtrlSetState(-1, $GUI_DISABLE)

EndIf

but have not been successful thusfar. Can someone offer assistance please?

[Melba23]

Shark007,

Only way I can think of is to use Dummy controls to delineate the sets of controls on each tab and then use GUICtrlSetState in a loop. Look at this:

expandcollapse popup

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton1 = GUICtrlCreateButton("Toggle Tab 1",  10, 10, 80, 30)
$hButton2 = GUICtrlCreateButton("Toggle Tab 2", 100, 10, 80, 30)

$hTab = GUICtrlCreateTab(10, 100, 480, 380)

$hTab1 = GUICtrlCreateTabItem("Tab 1")
    $hStart1 = GUICtrlCreateDummy()
    For $i = 1 To 10
        GUICtrlCreateCheckbox($i, 10, 120 + $i * 20, 50, 15)
    Next
    $hStop1 = GUICtrlCreateDummy()

$hTab2 = GUICtrlCreateTabItem("Tab 2")
    $hStart2 = GUICtrlCreateDummy()
    For $i = 1 To 10
        GUICtrlCreateCheckbox(100 + $i, 10, 120 + $i * 20, 50, 15)
    Next
    $hStop2 = GUICtrlCreateDummy()

GUICtrlCreateTabItem("")    ; end tabitem definition

GUISetState()

$fTab1State = True
$fTab2State = True

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton1
            If $fTab1State = True Then
                $iState = $GUI_DISABLE
            Else
                $iState = $GUI_ENABLE
            EndIf
            For $i = $hStart1 To $hStop1
                GUICtrlSetState($i, $iState)
            Next
            $fTab1State = Not $fTab1State
        Case $hButton2
            If $fTab2State = True Then
                $iState = $GUI_DISABLE
            Else
                $iState = $GUI_ENABLE
            EndIf
            For $i = $hStart2 To $hStop2
                GUICtrlSetState($i, $iState)
            Next
            $fTab2State = Not $fTab2State
    EndSwitch

WEnd

Ask if anything is unclear.

M23