Difference between revisions of "Managing Multiple GUIs"

From AutoIt Wiki
Jump to navigation Jump to search
m (variable renameing: $hButton >> $idButton)
m (MessageLoop Mode: Tidy example + Variable declaration)
Line 5: Line 5:
  
 
Let us start with ''MessageLoop'' mode as this is where most new coders run into difficulties with multiple GUIs.  This example script illustrates the problem - it exits when the '''[X]''' is clicked on either GUI:
 
Let us start with ''MessageLoop'' mode as this is where most new coders run into difficulties with multiple GUIs.  This example script illustrates the problem - it exits when the '''[X]''' is clicked on either GUI:
<syntaxhighlight lang="autoit"> #include <GUIConstantsEx.au3>
+
<syntaxhighlight lang="autoit">
+
#include <GUIConstantsEx.au3>
Global $idButton3 = 9999
+
 
+
Global $g_idButton3 = 9999
gui1()
+
 
+
gui1()
Func gui1()
+
 
    $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
+
Func gui1()
    $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
+
Local $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
    $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
+
Local $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
    GUISetState()
+
Local $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
+
GUISetState()
    While 1
+
 
        Switch GUIGetMsg()
+
While 1
            Case $GUI_EVENT_CLOSE
+
Switch GUIGetMsg()
                ExitLoop
+
Case $GUI_EVENT_CLOSE
            Case $idButton1
+
ExitLoop
                MsgBox("", "MsgBox 1", "Test from Gui 1")
+
Case $idButton1
            Case $idButton2
+
MsgBox("", "MsgBox 1", "Test from Gui 1")
                GUICtrlSetState($idButton2, $GUI_DISABLE)
+
Case $idButton2
                gui2()
+
GUICtrlSetState($idButton2, $GUI_DISABLE)
            Case $idButton3
+
gui2()
                MsgBox("", "MsgBox 2", "Test from Gui 2")  
+
Case $g_idButton3
        EndSwitch
+
MsgBox("", "MsgBox 2", "Test from Gui 2")
    WEnd
+
EndSwitch
EndFunc  ;==>gui1
+
WEnd
+
EndFunc  ;==>gui1
Func gui2()
+
 
    $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
+
Func gui2()
    $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
+
Local $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
    GUISetState()
+
Local $g_idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
EndFunc  ;==>gui2 </syntaxhighlight>
+
GUISetState()
 +
EndFunc  ;==>gui2
 +
</syntaxhighlight>
 +
 
 
The script exits because it has a single ''GUIGetMsg'' loop and the ''$GUI_EVENT_CLOSE'' message is received when either '''[X]''' is clicked - we have no way of telling the messages from the two GUIs apart.
 
The script exits because it has a single ''GUIGetMsg'' loop and the ''$GUI_EVENT_CLOSE'' message is received when either '''[X]''' is clicked - we have no way of telling the messages from the two GUIs apart.
  
 
The simplest solution is to disable the first GUI while the second is displayed:
 
The simplest solution is to disable the first GUI while the second is displayed:
<syntaxhighlight lang="autoit"> #include <GUIConstantsEx.au3>
+
<syntaxhighlight lang="autoit">
+
#include <GUIConstantsEx.au3>
gui1()
+
 
+
gui1()
Func gui1()
+
 
    $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
+
Func gui1()
    $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
+
Local $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
    $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
+
Local $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
    GUISetState()
+
Local $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
+
GUISetState()
    While 1
+
 
        Switch GUIGetMsg()
+
While 1
            Case $GUI_EVENT_CLOSE
+
Switch GUIGetMsg()
                ExitLoop
+
Case $GUI_EVENT_CLOSE
            Case $idButton1
+
ExitLoop
                MsgBox("", "MsgBox 1", "Test from Gui 1")
+
Case $idButton1
            Case $idButton2
+
MsgBox("", "MsgBox 1", "Test from Gui 1")
                ; Disable the first GUI
+
Case $idButton2
                GUISetState(@SW_DISABLE, $hGUI1)
+
; Disable the first GUI
                gui2()
+
GUISetState(@SW_DISABLE, $hGUI1)
                ; Re-enable the first GUI
+
gui2()
                GUISetState(@SW_ENABLE, $hGUI1)
+
; Re-enable the first GUI
        EndSwitch
+
GUISetState(@SW_ENABLE, $hGUI1)
    WEnd
+
EndSwitch
EndFunc  ;==>gui1
+
WEnd
+
EndFunc  ;==>gui1
Func gui2()
+
 
    $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
+
Func gui2()
    $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
+
Local $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
    GUISetState()
+
Local $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
+
GUISetState()
    While 1
+
 
        ; We can only get messages from the second GUI
+
While 1
        Switch GUIGetMsg()
+
; We can only get messages from the second GUI
            Case $GUI_EVENT_CLOSE
+
Switch GUIGetMsg()
                GUIDelete($hGUI2)
+
Case $GUI_EVENT_CLOSE
                ExitLoop
+
GUIDelete($hGUI2)
            Case $idButton3
+
ExitLoop
                MsgBox("", "MsgBox 2", "Test from Gui 2")
+
Case $idButton3
EndSwitch
+
MsgBox("", "MsgBox 2", "Test from Gui 2")
WEnd
+
EndSwitch
EndFunc  ;==>gui2 </syntaxhighlight>
+
WEnd
 +
 
 +
EndFunc  ;==>gui2
 +
</syntaxhighlight>
 +
 
 
This may well be all you need, but it does mean that we cannot action any of the controls on the first GUI until we close the second.  And importantly we remain blocked in the ''While...WEnd'' loop within the ''gui2'' function - go and read the [[Interrupting a running function]] tutorial to see why this is less than ideal.
 
This may well be all you need, but it does mean that we cannot action any of the controls on the first GUI until we close the second.  And importantly we remain blocked in the ''While...WEnd'' loop within the ''gui2'' function - go and read the [[Interrupting a running function]] tutorial to see why this is less than ideal.
  
 
So how can we deal with multiple GUIs visible at the same time?  Fortunately AutoIt offers us a simple way to differentiate between GUIs in ''MessageLoop'' mode.  Normally we use code like this in our idle loop to detect the messages sent by our GUI and its controls:
 
So how can we deal with multiple GUIs visible at the same time?  Fortunately AutoIt offers us a simple way to differentiate between GUIs in ''MessageLoop'' mode.  Normally we use code like this in our idle loop to detect the messages sent by our GUI and its controls:
<syntaxhighlight lang="autoit"> Switch GUIGetMsg()
+
<syntaxhighlight lang="autoit">
    Case $GUI_EVENT_CLOSE
+
Switch GUIGetMsg()
        ; Code
+
Case $GUI_EVENT_CLOSE
    Case $idButton1
+
; Code
        ; Code
+
Case $idButton1
EndSwitch </syntaxhighlight>  
+
; Code
 +
EndSwitch
 +
</syntaxhighlight>  
 +
 
 
But when dealing with multiple GUIs, we need to use the "''advanced''" parameter when we call ''GUIGetMsg''.  As explained in the Help file, the function then returns an array instead of a single value.  This array includes information on what exactly triggered the message, just what we need to distinguish the message that was sent (element['''0'''] of the array) and which GUI sent it (element['''1''']).  We can then amend our simple Switch statement above to read like this:  
 
But when dealing with multiple GUIs, we need to use the "''advanced''" parameter when we call ''GUIGetMsg''.  As explained in the Help file, the function then returns an array instead of a single value.  This array includes information on what exactly triggered the message, just what we need to distinguish the message that was sent (element['''0'''] of the array) and which GUI sent it (element['''1''']).  We can then amend our simple Switch statement above to read like this:  
<syntaxhighlight lang="autoit"> $aMsg = GUIGetMsg(1) ; Use advanced parameter to get an array returned
+
<syntaxhighlight lang="autoit">
 +
$aMsg = GUIGetMsg(1) ; Use advanced parameter to get an array returned
  
Switch $aMsg[1] ; First check which GUI sent the message
+
Switch $aMsg[1] ; First check which GUI sent the message
    Case $hGUI1
+
Case $hGUI1
        Switch $aMsg[0] ; Now check for the messages sent from $hGUI1
+
Switch $aMsg[0] ; Now check for the messages sent from $hGUI1
            Case $GUI_EVENT_CLOSE  
+
Case $GUI_EVENT_CLOSE
                ; Code
+
; Code
            Case $hControl
+
Case $hControl
                ; Code
+
; Code
        EndSwitch
+
EndSwitch
    Case $hGUI2
+
Case $hGUI2
        Switch $aMsg[0] ; Now check for the messages sent from $hGUI2
+
Switch $aMsg[0] ; Now check for the messages sent from $hGUI2
            Case $GUI_EVENT_CLOSE
+
Case $GUI_EVENT_CLOSE
                ; Code
+
; Code
            Case $idButton3
+
Case $idButton3
                ; Code
+
; Code
        EndSwitch
+
EndSwitch
EndSwitch </syntaxhighlight>
+
EndSwitch
 +
</syntaxhighlight>
 
Although this looks complicated, if you take a moment to study it and you will quickly realise it is simply two ''Switch'' structures within an outer ''Switch''.  You have already dealt with a single ''Switch'' structure for a single GUI. All you are doing here is determining which ''Switch'' structure you want to use, and that depends on the GUI which sent the message which is why we need the outer ''Switch'' structure as a wrapper.
 
Although this looks complicated, if you take a moment to study it and you will quickly realise it is simply two ''Switch'' structures within an outer ''Switch''.  You have already dealt with a single ''Switch'' structure for a single GUI. All you are doing here is determining which ''Switch'' structure you want to use, and that depends on the GUI which sent the message which is why we need the outer ''Switch'' structure as a wrapper.
  
 
So here is an example of how to manage two GUIs simultaneously using the "''advanced''" parameter with ''GUIGetMsg'':
 
So here is an example of how to manage two GUIs simultaneously using the "''advanced''" parameter with ''GUIGetMsg'':
<syntaxhighlight lang="autoit"> #include <GUIConstantsEx.au3>
+
<syntaxhighlight lang="autoit">
+
#include <GUIConstantsEx.au3>
Global $hGUI2 = 9999, $idButton3 ; Predeclare the variables with dummy values to prevent firing the Case statements, only for GUI this time
+
 
+
Global $g_hGUI2 = 9999, $g_idButton3 ; Predeclare the variables with dummy values to prevent firing the Case statements, only for GUI this time
gui1()
+
 
+
gui1()
Func gui1()
+
 
    $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
+
Func gui1()
    $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
+
Local $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
    $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
+
Local $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
    GUISetState()
+
Local $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
+
GUISetState()
    While 1
+
 
        $aMsg = GUIGetMsg(1) ; Use advanced parameter to get array
+
Local $aMsg
        Switch $aMsg[1] ; check which GUI sent the message
+
While 1
            Case $hGUI1
+
$aMsg = GUIGetMsg(1) ; Use advanced parameter to get array
                Switch $aMsg[0] ; Now check for the messages for $hGUI1
+
Switch $aMsg[1] ; check which GUI sent the message
                    Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we exit <<<<<<<<<<<<<<<
+
Case $hGUI1
                        ExitLoop
+
Switch $aMsg[0] ; Now check for the messages for $hGUI1
                    Case $idButton1
+
Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we exit <<<<<<<<<<<<<<<
                        MsgBox("", "MsgBox 1", "Test from Gui 1")
+
ExitLoop
                    Case $idButton2
+
Case $idButton1
                        GUICtrlSetState($idButton2, $GUI_DISABLE)
+
MsgBox("", "MsgBox 1", "Test from Gui 1")
                        gui2()
+
Case $idButton2
                EndSwitch
+
GUICtrlSetState($idButton2, $GUI_DISABLE)
            Case $hGUI2
+
gui2()
                Switch $aMsg[0] ; Now check for the messages for $hGUI2
+
EndSwitch
                    Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we just delete the GUI <<<<<<<<<<<<<<<
+
Case $g_hGUI2
                        GUIDelete($hGUI2)
+
Switch $aMsg[0] ; Now check for the messages for $g_hGUI2
                        GUICtrlSetState($idButton2, $GUI_ENABLE)
+
Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we just delete the GUI <<<<<<<<<<<<<<<
                    Case $idButton3
+
GUIDelete($g_hGUI2)
                        MsgBox("", "MsgBox", "Test from Gui 2")
+
GUICtrlSetState($idButton2, $GUI_ENABLE)
                EndSwitch
+
Case $g_idButton3
        EndSwitch
+
MsgBox("", "MsgBox", "Test from Gui 2")
    WEnd
+
EndSwitch
EndFunc  ;==>gui1
+
EndSwitch
+
WEnd
Func gui2()
+
EndFunc  ;==>gui1
    $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
+
 
    $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
+
Func gui2()
    GUISetState()
+
$g_hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
EndFunc  ;==>gui2 </syntaxhighlight>
+
Local $g_idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
 +
GUISetState()
 +
EndFunc  ;==>gui2
 +
</syntaxhighlight>
 +
 
 
As you can see, we have a single ''While...WEnd'' loop which distinguishes between the two GUIs, both GUIs and their controls remain active and we stay in the main idle loop while we wait (you did read that other tutorial I hope!).
 
As you can see, we have a single ''While...WEnd'' loop which distinguishes between the two GUIs, both GUIs and their controls remain active and we stay in the main idle loop while we wait (you did read that other tutorial I hope!).
  

Revision as of 19:06, 16 April 2017

Introduction

Having several GUIs on the screen at the same time is fairly common but structuring your code to deal with this can seem quite daunting. However, as I hope this tutorial will demonstrate, it is nowhere near as difficult as it first appears.

MessageLoop Mode

Let us start with MessageLoop mode as this is where most new coders run into difficulties with multiple GUIs. This example script illustrates the problem - it exits when the [X] is clicked on either GUI:

#include <GUIConstantsEx.au3>

Global $g_idButton3 = 9999

gui1()

Func gui1()
	Local $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
	Local $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
	Local $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
	GUISetState()

	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton1
				MsgBox("", "MsgBox 1", "Test from Gui 1")
			Case $idButton2
				GUICtrlSetState($idButton2, $GUI_DISABLE)
				gui2()
			Case $g_idButton3
				MsgBox("", "MsgBox 2", "Test from Gui 2")
		EndSwitch
	WEnd
EndFunc   ;==>gui1

Func gui2()
	Local $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
	Local $g_idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
	GUISetState()
EndFunc   ;==>gui2

The script exits because it has a single GUIGetMsg loop and the $GUI_EVENT_CLOSE message is received when either [X] is clicked - we have no way of telling the messages from the two GUIs apart.

The simplest solution is to disable the first GUI while the second is displayed:

#include <GUIConstantsEx.au3>

gui1()

Func gui1()
	Local $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
	Local $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
	Local $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
	GUISetState()

	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton1
				MsgBox("", "MsgBox 1", "Test from Gui 1")
			Case $idButton2
				; Disable the first GUI
				GUISetState(@SW_DISABLE, $hGUI1)
				gui2()
				; Re-enable the first GUI
				GUISetState(@SW_ENABLE, $hGUI1)
		EndSwitch
	WEnd
EndFunc   ;==>gui1

Func gui2()
	Local $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
	Local $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
	GUISetState()

	While 1
		; We can only get messages from the second GUI
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				GUIDelete($hGUI2)
				ExitLoop
			Case $idButton3
				MsgBox("", "MsgBox 2", "Test from Gui 2")
		EndSwitch
	WEnd

EndFunc   ;==>gui2

This may well be all you need, but it does mean that we cannot action any of the controls on the first GUI until we close the second. And importantly we remain blocked in the While...WEnd loop within the gui2 function - go and read the Interrupting a running function tutorial to see why this is less than ideal.

So how can we deal with multiple GUIs visible at the same time? Fortunately AutoIt offers us a simple way to differentiate between GUIs in MessageLoop mode. Normally we use code like this in our idle loop to detect the messages sent by our GUI and its controls:

Switch GUIGetMsg()
	Case $GUI_EVENT_CLOSE
		; Code
	Case $idButton1
		; Code
EndSwitch

But when dealing with multiple GUIs, we need to use the "advanced" parameter when we call GUIGetMsg. As explained in the Help file, the function then returns an array instead of a single value. This array includes information on what exactly triggered the message, just what we need to distinguish the message that was sent (element[0] of the array) and which GUI sent it (element[1]). We can then amend our simple Switch statement above to read like this:

$aMsg = GUIGetMsg(1) ; Use advanced parameter to get an array returned

Switch $aMsg[1] ; First check which GUI sent the message
	Case $hGUI1
		Switch $aMsg[0] ; Now check for the messages sent from $hGUI1
			Case $GUI_EVENT_CLOSE
				; Code
			Case $hControl
				; Code
		EndSwitch
	Case $hGUI2
		Switch $aMsg[0] ; Now check for the messages sent from $hGUI2
			Case $GUI_EVENT_CLOSE
				; Code
			Case $idButton3
				; Code
		EndSwitch
EndSwitch

Although this looks complicated, if you take a moment to study it and you will quickly realise it is simply two Switch structures within an outer Switch. You have already dealt with a single Switch structure for a single GUI. All you are doing here is determining which Switch structure you want to use, and that depends on the GUI which sent the message which is why we need the outer Switch structure as a wrapper.

So here is an example of how to manage two GUIs simultaneously using the "advanced" parameter with GUIGetMsg:

#include <GUIConstantsEx.au3>

Global $g_hGUI2 = 9999, $g_idButton3 ; Predeclare the variables with dummy values to prevent firing the Case statements, only for GUI this time

gui1()

Func gui1()
	Local $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
	Local $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
	Local $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
	GUISetState()

	Local $aMsg 
	While 1
		$aMsg = GUIGetMsg(1) ; Use advanced parameter to get array
		Switch $aMsg[1] ; check which GUI sent the message
			Case $hGUI1
				Switch $aMsg[0] ; Now check for the messages for $hGUI1
					Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we exit <<<<<<<<<<<<<<<
						ExitLoop
					Case $idButton1
						MsgBox("", "MsgBox 1", "Test from Gui 1")
					Case $idButton2
						GUICtrlSetState($idButton2, $GUI_DISABLE)
						gui2()
				EndSwitch
			Case $g_hGUI2
				Switch $aMsg[0] ; Now check for the messages for $g_hGUI2
					Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we just delete the GUI <<<<<<<<<<<<<<<
						GUIDelete($g_hGUI2)
						GUICtrlSetState($idButton2, $GUI_ENABLE)
					Case $g_idButton3
						MsgBox("", "MsgBox", "Test from Gui 2")
				EndSwitch
		EndSwitch
	WEnd
EndFunc   ;==>gui1

Func gui2()
	$g_hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
	Local $g_idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
	GUISetState()
EndFunc   ;==>gui2

As you can see, we have a single While...WEnd loop which distinguishes between the two GUIs, both GUIs and their controls remain active and we stay in the main idle loop while we wait (you did read that other tutorial I hope!).

OnEvent Mode

Coders using OnEvent mode do not usually find the same problem with multiple GUIs as they can code separate functions for each $GUI_EVENT_CLOSE as shown here:

 #include <GUIConstantsEx.au3>
 
 Opt("GUIOnEventMode", 1)
 
 Global $hGUI2, $idButton2 ; Predeclare these variables
 
 gui1()
 
 Func gui1()
     $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
     GUISetOnEvent($GUI_EVENT_CLOSE, "On_Close_Main") ; Run this function when the main GUI [X] is clicked
     $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
     GUICtrlSetOnEvent(-1, "On_Button1")
     $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
     GUICtrlSetOnEvent(-1, "On_Button2")
     GUISetState()
 
     While 1
         Sleep(10)
     WEnd
 EndFunc   ;==>gui1
 
 Func gui2()
     $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
     GUISetOnEvent($GUI_EVENT_CLOSE, "On_Close_Secondary") ; Run this function when the secondary GUI [X] is clicked
     $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
     GUICtrlSetOnEvent(-1, "On_Button3")
     GUISetState()
 EndFunc   ;==>gui2
 
 Func On_Close_Main()
     Exit
 EndFunc
 
 Func On_Close_Secondary()
     GUIDelete($hGUI2)
     GUICtrlSetState($idButton2, $GUI_ENABLE)
 EndFunc
 
 Func On_Button1()
     MsgBox("", "MsgBox 1", "Test from Gui 1")
 EndFunc
 
 Func On_Button2()
     GUICtrlSetState($idButton2, $GUI_DISABLE)
     gui2()
 EndFunc
 
 Func On_Button3()
     MsgBox("", "MsgBox 2", "Test from Gui 2")
 EndFunc

But did you realise that you can also use what some people think of as a hybrid mode - using common OnEvent functions and then determining the specific GUI or control which called the function within the function? As an added bonus, this approach may, depending on the circumstances, let you send parameters to the functions you call - something that you normally cannot do in OnEvent mode.

 #include <GUIConstantsEx.au3>
 
 Opt("GUIOnEventMode", 1)
 
 Global $hGUI1, $hGUI2 = 9999, $idButton1, $idButton2, $idButton3 = 9999 ; Predeclare the variables with dummy values to prevent firing the Case statements
 
 gui1()
 
 Func gui1()
     $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
     GUISetOnEvent($GUI_EVENT_CLOSE, "On_Close") ; Call a common GUI close function
     $idButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
     GUICtrlSetOnEvent(-1, "On_Button") ; Call a common button function
     $idButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
     GUICtrlSetOnEvent(-1, "On_Button") ; Call a common button function
     GUISetState()
 
     While 1
         Sleep(10)
     WEnd
 EndFunc   ;==>gui1
 
 Func gui2()
     $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
     GUISetOnEvent($GUI_EVENT_CLOSE, "On_Close") ; Call a common GUI close function
     $idButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
     GUICtrlSetOnEvent(-1, "On_Button") ; Call a common button function
     GUISetState()
 EndFunc   ;==>gui2
 
 Func On_Close()
     Switch @GUI_WINHANDLE ; See which GUI sent the CLOSE message
         Case $hGUI1
             Exit ; If it was this GUI - we exit <<<<<<<<<<<<<<<
         Case $hGUI2
             GUIDelete($hGUI2) ; If it was this GUI - we just delete the GUI <<<<<<<<<<<<<<<
             GUICtrlSetState($idButton2, $GUI_ENABLE)
     EndSwitch
 EndFunc
 
 Func On_Button()
     Switch @GUI_CTRLID ; See which button sent the message
         Case $idButton1
             MessageBox(1) ; We can call a function with parameters here <<<<<<<<<<<<<<<<<<<
         Case $idButton2
             GUICtrlSetState($idButton2, $GUI_DISABLE)
             gui2()
         Case $idButton3
             MessageBox(2) ; We can call a function with parameters here <<<<<<<<<<<<<<<<<<<
     EndSwitch
 EndFunc
 
 Func MessageBox($iIndex)
     MsgBox("", "MsgBox " & $iIndex, "Test from Gui " & $iIndex)
 EndFunc

Summary

So you see that managing multiple GUIS is not as difficult as you might think. One of these methods is bound to suit your script, but do not try and mix them - only one method per script please!