Function Reference

_GUICtrlComboBoxEx_GetListArray

Retrieves all items from the list portion of a ComboBox control

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetListArray ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Returns an array in the following format:
    [0] - Number of items
    [1] - Item 1
    [2] - Item 2
    [n] - Item n

Related

_GUICtrlComboBoxEx_GetList

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUI, $aItem, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Get List Array", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Add files
        _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES, False)

        ; Get List
        $aItem = _GUICtrlComboBoxEx_GetListArray($hCombo)

        For $x = 1 To $aItem[0]
                MemoWrite($aItem[$x])
        Next

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite