Function Reference

_GUICtrlComboBoxEx_SetExtendedUI

Select either the default user interface or the extended user interface

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetExtendedUI ( $hWnd [, $bExtended = False] )

Parameters

$hWnd Handle to the control
$bExtended [optional] Specifies whether the combo box uses the extended

Return Value

Success: True.
Failure: False.

Remarks

By default, the F4 key opens or closes the list and the DOWN ARROW changes the current selection.

In a ComboBox with the extended user interface, the F4 key is disabled and pressing the DOWN ARROW key opens the drop-down list.

Related

_GUICtrlComboBoxEx_GetExtendedUI

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("ComboBoxEx Get/Set ExtendedUI (v" & @AutoItVersion & ")", 400, 300)
        Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        For $x = 0 To 8
                _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
        Next

        ; Get Extended UI
        MemoWrite("Extended UI: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

        ; Set Extended UI
        _GUICtrlComboBoxEx_SetExtendedUI($hCombo, True)

        ; Get Extended UI
        MemoWrite("Extended UI: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite