Function Reference

_GUICtrlComboBox_SetEditSel

Select characters in the edit control of a ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetEditSel($hWnd, $iStart, $iStop)

Parameters

$hWnd Control ID/Handle to the control
$iStart Starting position
$iStop Ending postions

Return Value

Success: True
Failure: False If the message is sent to a ComboBox with the $CBS_DROPDOWN or $CBS_DROPDOWNLIST style

Remarks

The positions are zero-based. The first character of the edit control is in the zero position.
If $iStop is –1, all text from the starting position to the last character in the edit control is selected.

The first character after the last selected character is in the ending position.

For example, to select the first four characters of the edit control, use a starting position
of 0 and an ending position of 4.

Related

_GUICtrlComboBox_GetEditSel, _GUICtrlComboBox_ReplaceEditSel

Example


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Check ClassName being passed to ComboBox/ComboBoxEx functions, set to True and use a handle to another control to see it work

Global $iMemo

_Main()

Func _Main()
    Local $aSel, $hCombo

    ; Create GUI
    GUICreate("ComboBox Set Edit Sel", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Add files
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Select Item
    _GUICtrlComboBox_SetCurSel($hCombo, 2)

    ; Set Edit Sel
    _GUICtrlComboBox_SetEditSel($hCombo, 0, 4)

    ; Get Edit Sel
    $aSel = _GUICtrlComboBox_GetEditSel($hCombo)
    MemoWrite(StringFormat("Edit Sel: %d - %d", $aSel[0], $aSel[1]))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite