Function Reference

_GUICtrlListView_GetViewLarge

Determines whether the view mode is in large icon mode

#include <GuiListView.au3>
_GUICtrlListView_GetViewLarge($hWnd)

Parameters

$hWnd Control ID/Handle to the control

Return Value

True: View is in large icon mode
False: View is not in large icon mode

Remarks

Minimum OS - Windows XP.

Related

_GUICtrlListView_GetView

Example


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Get View Large Icon", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; Add items
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Set view
    _GUICtrlListView_SetView($hListView, 1)
    MsgBox(4160, "Information", "View Large: " & _GUICtrlListView_GetViewLarge($hListView))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main