Sets text in a control from a file
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamFromFile ( $hWnd, $sFileSpec [, $iFileEncoding = Default] )
| $hWnd | Handle to the control |
| $sFileSpec | file specification |
| $iFileEncoding | [optional] file encoding specification (See FileOpen() to more info). Default: $FO_READ. |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 1021 - unable to open $sFileSpec 1022 - file is empty 700 - attempt to stream in too many characters |
If text is selected, replaces selection, else replaces all text in the control.
Call _GUICtrlRichEdit_SetLimitOnText() to increase the number of characters the control can contain.
_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile
Search EM_STREAMIN in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetData($idLblMsg, "Streamed to gcre.rtf")
Case 2
_GUICtrlRichEdit_SetText($hRichEdit, "")
_GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetData($idLblMsg, "Streamed from gcre.rtf")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
_GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetData($idLblMsg, "Replaced selection: an intentional mess!")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example