Retrieves the bounding rectangle of a part
#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRectEx ( $hWnd, $iPart )
| $hWnd | Handle to the control |
| $iPart | 0-based part index. If the control is in simple mode this field is ignored and the rectangle of the status bar is returned. |
| Success: | a $tagRECT structure that receives the bounding rectangle. |
| Failure: | sets the @error flag to non-zero. |
$tagRECT, _GUICtrlStatusBar_GetRect
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("StatusBar Get RectEx (v" & @AutoItVersion & ")", 400, 300)
Local $hStatus = _GUICtrlStatusBar_Create($hGUI)
; Create memo control
$g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Set/Get parts
Local $aParts[3] = [75, 150, -1]
_GUICtrlStatusBar_SetParts($hStatus, $aParts)
; Get part 0 rectangles
Local $tRECT = _GUICtrlStatusBar_GetRectEx($hStatus, 0)
MemoWrite("Part 0 left ...: " & DllStructGetData($tRECT, "Left"))
MemoWrite("Part 0 top ....: " & DllStructGetData($tRECT, "Top"))
MemoWrite("Part 0 right ..: " & DllStructGetData($tRECT, "Right"))
MemoWrite("Part 0 bottom .: " & DllStructGetData($tRECT, "Bottom"))
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite