Function Reference

_GUICtrlTab_GetItemRectEx

Retrieves the bounding rectangle for a tab

#include <GuiTab.au3>
_GUICtrlTab_GetItemRectEx ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex 0-based item index

Return Value

Returns a $tagRECT structure that receives the rectangle of the tab, in viewport coordinates.

Related

$tagRECT, _GUICtrlTab_GetItemRect

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        ; Create GUI
        GUICreate("Tab Control Get Item RectEx (v" & @AutoItVersion & ")", 400, 300)
        Local $idTab = GUICtrlCreateTab(2, 2, 396, 296)
        GUISetState(@SW_SHOW)

        ; Add tabs
        _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
        _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
        _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

        ; Get item 0 rectangle
        Local $tRECT = _GUICtrlTab_GetItemRectEx($idTab, 0)
        Local $sRect = StringFormat("[%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
                        DllStructGetData($tRECT, "Top"), _
                        DllStructGetData($tRECT, "Right"), _
                        DllStructGetData($tRECT, "Bottom"))
        MsgBox($MB_SYSTEMMODAL, "Information", "Display rectangle: " & $sRect)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example