Function Reference

_GUICtrlTreeView_SetIndent

Sets the width of indentation for a tree-view control and redraws the control to reflect the new width

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetIndent($hWnd, $iIndent)

Parameters

$hWnd Control ID/Handle to the control
$iIndent Width, in pixels, of the indentation.

Return Value

None.

Remarks

If the $iIndent parameter is less than the system-defined minimum width, the new width is set to the
system-defined minimum.

Related

_GUICtrlTreeView_GetIndent

Example


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Check ClassName being passed to functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()

    Local $hImage, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Indent", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox(4160, "Information", "Indent: " & _GUICtrlTreeView_GetIndent($hTreeView))

    _GUICtrlTreeView_SetIndent($hTreeView, 25)

    MsgBox(4160, "Information", "Indent: " & _GUICtrlTreeView_GetIndent($hTreeView))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main