Provides information about sessions established on a server
#include <NetShare.au3>
_Net_Share_SessionEnum ( [$sServer = "" [, $sClientName = "" [, $sUserName = ""]]] )
| $sServer | [optional] String that specifies the DNS or NetBIOS name of the remote server on which the function is to execute. If this parameter is blank the local computer is used. |
| $sClientName | [optional] Specifies the name of the computer session for which information is to be returned. If this parameter is blank, the function returns information for all computer sessions on the server. |
| $sUserName | [optional] Specifies the name of the user for which information is to be returned. If this parameter is blank, the function returns information for all users. |
| Success: | an array with the following format: [0][0] - Number of entries in array [1][0] - Name of the computer that established the session [1][1] - Name of the user who established the session [1][2] - Number of files, devices, and pipes opened during the session [1][3] - Number of seconds the session has been active [1][4] - Number of seconds the session has been idle [1][5] - Specifies how the user established the session: 1 - User established session using a guest account 2 - User established session without using password encryption [1][6] - Specifies the type of client that established the session [1][7] - Name of the transport that the client is using |
| Failure: | sets the @error flag to non-zero. |
Only members of the Administrators or Server Operators local group can execute this function.
_Net_Share_ConnectionEnum, _Net_Share_FileEnum, _Net_Share_ShareEnum
Search NetSessionEnum in MSDN Library.
#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
Local $sServer, $aInfo
; Create GUI
GUICreate("NetShare", 400, 300)
; Create memo control
$g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Get server and share information
$sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
If @error Then Exit
; Enumerate network sessions
$aInfo = _Net_Share_SessionEnum($sServer, @ComputerName)
MemoWrite("Error ..........: " & @error)
MemoWrite("Entries read ...: " & $aInfo[0][0])
For $iI = 1 To $aInfo[0][0]
MemoWrite("Computer name ..: " & $aInfo[$iI][0])
MemoWrite("User name.......: " & $aInfo[$iI][1])
MemoWrite("Resources open .: " & $aInfo[$iI][2])
MemoWrite("Seconds active .: " & $aInfo[$iI][3])
MemoWrite("Seconds idle ...: " & $aInfo[$iI][4])
MemoWrite("Connection type : " & $aInfo[$iI][5])
MemoWrite("Client type ....: " & $aInfo[$iI][6])
MemoWrite("Transport ......: " & $aInfo[$iI][7])
MemoWrite()
Next
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite