Function Reference


ClipGet

Retrieves text from the clipboard.

ClipGet ( )

Return Value

Success: a string containing the text on the clipboard.
Failure: sets the @error to non-zero.
@error: 1 = if clipboard is empty
2 = if contains a non-text entry.
3 or 4 = if cannot access the clipboard.

Remarks

When multiple selecting file/dir are stored in the clipboard, the filename/dirname are returned as texts separated by @LF.

Related

ClipPut

Example

#include <MsgBoxConstants.au3>

Example()

Func Example()
        ; Retrieve the data stored in the clipboard.
        Local $sData = ClipGet()

        ; Display the data returned by ClipGet.
        MsgBox($MB_SYSTEMMODAL, "", "The following data is stored in the clipboard: " & @CRLF & $sData)

        ; Add new data to the clipboard.
        ClipPut("A new string added to the clipboard.")

        ; Retrieve the data stored in the clipboard.
        $sData = ClipGet()

        ; Display the data returned by ClipGet.
        MsgBox($MB_SYSTEMMODAL, "", "The following data is now stored in the clipboard: " & @CRLF & $sData)
EndFunc   ;==>Example