Function Reference


_Date_Time_EncodeFileTime

Encodes and returns a $tagFILETIME structure

#include <Date.au3>
_Date_Time_EncodeFileTime ( $iMonth, $iDay, $iYear [, $iHour = 0 [, $iMinute = 0 [, $iSecond = 0 [, $iMSeconds = 0]]]] )

Parameters

$iMonth Month
$iDay Day
$iYear Year
$iHour [optional] Hour
$iMinute [optional] Minute
$iSecond [optional] Second
$iMSeconds [optional] Milliseconds

Return Value

Returns a $tagFILETIME structure.

Related

$tagFILETIME, _Date_Time_EncodeSystemTime

Example

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile

    ; Create GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Encode a file time
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    MemoWrite("Current date/time .: " & _Date_Time_FileTimeToStr($tFile))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite