Function Reference


_Date_Time_GetSystemTimes

Retrieves system timing information

#include <Date.au3>
_Date_Time_GetSystemTimes ( )

Return Value

Returns an array with the following format:
[0] - $tagFILETIME structure with the total system idle time
[1] - $tagFILETIME structure with the total system kernel mode time
[2] - $tagFILETIME structure with the total system user mode time

Related

$tagFILETIME

Example

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aTime

    ; Create GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get system times
    $aTime = _Date_Time_GetSystemTimes()

    MemoWrite("Idle time ...: " & _Date_Time_FileTimeToStr($aTime[0]))
    MemoWrite("System time .: " & _Date_Time_FileTimeToStr($aTime[1]))
    MemoWrite("User time ...: " & _Date_Time_FileTimeToStr($aTime[2]))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite