Function Reference


_GDIPlus_EffectCreateColorCurve

Creates a ColorBalance class effect object

#include <GDIPlus.au3>
_GDIPlus_EffectCreateColorCurve ( $iAdjustment, $iChannel, $iAdjustValue )

Parameters

$iAdjustment CurveAdjustments constant that specifies the adjustment to be applied ($GDIP_Adjust*).
$iChannel CurveChannel constant that specifies the color channel to which the adjustment applies ($GDIP_CurveChannel*).
$iAdjustValue Integer that specifies the intensity of the adjustment.
The range of acceptable values depends on which adjustment is being applied (see $GDIP_Adjust* constants).

Return Value

Success: a handle to an Effect object.
Failure: 0 and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GPID_ERR*).
@error: -1 - GDIPlus.dll does not support this function.
10 - Invalid parameters.

Remarks

When you are done with the Effect object, call _GDIPlus_EffectDispose() to release the resources.

Related

_GDIPlus_EffectCreate, _GDIPlus_EffectDispose

Example

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    If Not _GDIPlus_Startup() Or @extended < 6 Then
        MsgBox($MB_SYSTEMMODAL, "ERROR", "GDIPlus.dll v1.1 not available")
        Return
    EndIf

    Local $sFile = FileOpenDialog("Select an image", "", "Images (*.bmp;*.png;*.jpg;*.gif;*.tif)")
    If @error Or Not FileExists($sFile) Then Return

    Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)

    Local $iWidth = 600
    Local $iHeight = _GDIPlus_ImageGetHeight($hImage) * 600 / _GDIPlus_ImageGetWidth($hImage)

    Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    GUISetState(@SW_SHOW)

    Local $hEffect = _GDIPlus_EffectCreateColorCurve($GDIP_AdjustMidtone, $GDIP_CurveChannelRed, 30)
    _GDIPlus_BitmapApplyEffect($hImage, $hEffect)

    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GDIPlus_EffectDispose($hEffect)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Example