Sets the blend shape of a path gradient brush to create a custom blend based on a bell-shaped curve
#include <GDIPlus.au3>
_GDIPlus_PathBrushSetSigmaBlend ( $hPathGradientBrush, $fFocus [, $fScale = 1] )
| $hPathGradientBrush | Pointer to a PathGradientBrush object |
| $fFocus | Number in the range 0.0 to 1.0 that specifies where the center color will be at its highest intensity |
| $fScale | [optional] Number in the range 0.0 to 1.0 that specifies the maximum intensity of center color that gets blended with the boundary color |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GDIP_ERR* see GPIPlusConstants.au3). |
_GDIPlus_PathBrushSetLinearBlend
Search GdipSetPathGradientSigmaBlend in MSDN Library.
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $hGUI = GUICreate("GDI+", 200, 180)
GUISetState(@SW_SHOW)
_GDIPlus_Startup()
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
_GDIPlus_GraphicsClear($hGraphics, 0xFF000000)
Local $hPath = _GDIPlus_PathCreate()
_GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)
Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
_GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF00A000)
_GDIPlus_PathBrushSetSigmaBlend($hBrush, 0.25, 0.50)
_GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Clean up resources
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_PathDispose($hPath)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
EndFunc ;==>Example