Function Reference


_GUICtrlButton_GetNoteLength

Gets the length of the note text that may be displayed in the description for a command link button

#include <GuiButton.au3>
_GUICtrlButton_GetNoteLength ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Success: the length of the note text in WCHARs—not including any terminating NULL WCHAR.
Failure: 0.

Remarks

This function works only with the $BS_COMMANDLINK and $BS_DEFCOMMANDLINK button styles.

Windows Vista or later.

Related

_GUICtrlButton_GetNote, _GUICtrlButton_SetNote

See Also

Search BCM_GETNOTELENGTH in MSDN Library.

Example

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

; Note the controlID from these button(s) can NOT be read with GUICtrlRead

Example()

Func Example()
    Local $hGUI

    $hGUI = GUICreate("Buttons", 400, 400)
    $g_idMemo = GUICtrlCreateEdit("", 10, 65, 390, 325, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")

    Local $idBtn = _GUICtrlButton_Create($hGUI, "Button1", 10, 10, 160, 40, BitOR($BS_COMMANDLINK, $BS_DEFPUSHBUTTON, $BS_PUSHLIKE))
    _GUICtrlButton_SetNote($idBtn, "This is a test of Vista")

    GUISetState(@SW_SHOW)

    MemoWrite("Note: " & _GUICtrlButton_GetNote($idBtn))
    MemoWrite("Note Length: " & _GUICtrlButton_GetNoteLength($idBtn))
    MemoWrite("Button Text: " & _GUICtrlButton_GetText($idBtn))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite