Adds the names of directories and files
#include <GuiComboBox.au3>
_GUICtrlComboBox_AddDir ( $hWnd, $sFilePath [, $iAttributes = 0 [, $bBrackets = True]] )
| $hWnd | Control ID/Handle to the control |
| $sFilePath | Specifies an absolute path, relative path, or filename |
| $iAttributes | [optional] Specifies the attributes of the files or directories to be added: $DDL_READWRITE - Includes read-write files with no additional attributes $DDL_READONLY - Includes read-only files $DDL_HIDDEN - Includes hidden files $DDL_SYSTEM - Includes system files $DDL_DIRECTORY - Includes directories $DDL_ARCHIVE - Includes archived files $DDL_DRIVES - All mapped drives are added to the list $DDL_EXCLUSIVE - Includes only files with the specified attributes |
| $bBrackets | [optional] include/exclude brackets when $DDL_DRIVES is used |
| Success: | a 0-based index of the last name added. |
| Failure: | -1. |
If there is insufficient space to store the new strings, the return value is $CB_ERRSPACE.
Above constants require #include <DirConstants.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $idCombo
; Create GUI
GUICreate("ComboBox Add Dir", 400, 296)
$idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
GUISetState(@SW_SHOW)
; Add files
_GUICtrlComboBox_BeginUpdate($idCombo)
_GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($idCombo)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example