Function Reference


_GUICtrlEdit_SetTabStops

Sets the tab stops

#include <GuiEdit.au3>
_GUICtrlEdit_SetTabStops ( $hWnd, $aTabStops )

Parameters

$hWnd Control ID/Handle to the control
$aTabStops Array of tab stops in the following format:
[0] - Tab stop 1
[2] - Tab stop 2
[n] - Tab stop n

Return Value

True: All the tabs are set.
False: All the tabs are not set.

Example

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $aPartRightSide[3] = [190, 378, -1], $aTabStops[3] = [10, 30, 50]

    ; Create GUI
    $hGUI = GUICreate("Edit Set Tab Stops", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Set Margins
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Set Text
    _GUICtrlEdit_SetText($idEdit, @TAB & "1st" & @TAB & "2nd" & @TAB & "3rd")

    MsgBox($MB_SYSTEMMODAL, "Information", "Set Tab Stops")
    ; Set Tab Stops
    _GUICtrlEdit_SetTabStops($idEdit, $aTabStops)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example