Function Reference


_GUICtrlHeader_GetItemFlags

Returns the item flag information

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemFlags ( $hWnd, $iIndex )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index

Return Value

Returns the item flag information:
1 - Displays an image from an image list
2 - Text reads in the opposite direction from the text in the parent window
4 - Draws a down arrow on this item
8 - Draws a up arrow on this item

Related

_GUICtrlHeader_SetItemFlags

Example

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader

    ; Create GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Add columns
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Set column 1 flags
    _GUICtrlHeader_SetItemFlags($hHeader, 0, 4)

    ; Show column 1 flags
    MemoWrite("Column 1 flags: " & _GUICtrlHeader_GetItemFlags($hHeader, 0))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite