Function Reference

_GUICtrlHeader_SetItemAlign

Sets the item text alignment

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemAlign ( $hWnd, $iIndex, $iAlign )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index
$iAlign Text alignment:
    0 - Text is left-aligned
    1 - Text is right-aligned
    2 - Text is centered

Return Value

Success: True.
Failure: False.

Related

_GUICtrlHeader_GetItemAlign

Example

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUI, $hHeader

        ; Create GUI
        $hGUI = GUICreate("Header", 400, 300)
        $hHeader = _GUICtrlHeader_Create($hGUI)
        _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
        $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Add columns
        _GUICtrlHeader_AddItem($hHeader, "Column 0", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

        ; Set column 0 alignment
        _GUICtrlHeader_SetItemAlign($hHeader, 0, 2)

        ; Show column 0 alignment
        MemoWrite("Column 0 alignment: " & _GUICtrlHeader_GetItemAlign($hHeader, 0))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite