Function Reference


_GUICtrlHeader_SetItemDisplay

Returns the item display information

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemDisplay ( $hWnd, $iIndex, $iDisplay )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index
$iDisplay Item display information. Can be a combination of the following:
    1 - The item displays a bitmap
    2 - The bitmap appears to the right of text
    4 - The control's owner draws the item
    8 - The item displays a string

Return Value

Success: True.
Failure: False.

Related

_GUICtrlHeader_GetItemDisplay, _GUICtrlHeader_SetItemBitmap

Example

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUI, $hHeader, $hImage

        ; Create GUI
        $hGUI = GUICreate("Header", 400, 300)
        $hHeader = _GUICtrlHeader_Create($hGUI)
        _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
        $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Create an image list with images
        $hImage = _GUIImageList_Create(11, 11)
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
        _GUICtrlHeader_SetImageList($hHeader, $hImage)

        ; Add columns
        _GUICtrlHeader_AddItem($hHeader, "Column 0", 100, 0)
        _GUICtrlHeader_AddItem($hHeader, "Column 1", 100, 0, 1)
        _GUICtrlHeader_AddItem($hHeader, "Column 2", 100, 0, 2)
        _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

        ; Set column 0 bitmap
        _GUICtrlHeader_SetItemBitmap($hHeader, 0, _WinAPI_CreateSolidBitmap($hGUI, 0xFF00FF, 11, 11))

        ; Set column 0 display
        _GUICtrlHeader_SetItemDisplay($hHeader, 0, 1 + 2 + 8)

        ; Show column 0 display
        MemoWrite("Column 0 display: " & _GUICtrlHeader_GetItemDisplay($hHeader, 0))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite